Delphi 2010 中返回泛型接口的泛型方法

Question

给出下面的代码，这是实际代码的一个非常精简的版本，我收到以下错误：

[DCC Error] Unit3.pas(31): E2010 不兼容类型：'IXList.FindAll。 S>'和 'T​​XList.FindAll.S>'

在 FindAll 中功能。

我真的不明白为什么，因为之前非常相似的功能没有问题。

谁能解释一下吗？
是我的问题还是编译器的错误？

单元3；

interface
uses Generics.Collections;

type
  IXList<T> = interface
  end;

  TXList<T: class> = class(TList<T>, IXList<T>)
  protected
    FRefCount: Integer;
    function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
    function _AddRef: Integer; stdcall;
    function _Release: Integer; stdcall;
  public
    function Find: IXList<T>;
    function FindAll<S>: IXList<S>;
  end;

implementation
uses Windows;

function TXList<T>.Find: IXList<T>;
begin
  Result := TXList<T>.Create;
end;

function TXList<T>.FindAll<S>: IXList<S>;
begin
  Result := TXList<S>.Create; // Error here  
end;

function TXList<T>.QueryInterface(const IID: TGUID; out Obj): HResult;
begin
  Result := E_NoInterface;
end;

function TXList<T>._AddRef: Integer;
begin
  InterlockedIncrement(FRefCount);
end;

function TXList<T>._Release: Integer;
begin
  InterlockedDecrement(FRefCount);
  if FRefCount = 0 then Self.Destroy;
end;

end.

感谢您的回答！ 这似乎是一个编译器错误，有一个可接受的解决方法。

通过将接口声明为

IXList<T: class> = interface
   function GetEnumerator: TList<T>.TEnumerator;
end;

并实现 findall，

function TXList<T>.FindAll<S>: IXList<S>;
var
  lst: TXList<S>;
  i: T;
begin
  lst := TXList<S>.Create;
  for i in Self do
    if i.InheritsFrom(S) then lst.Add(S(TObject(i)));

  Result := IXList<S>(IUnknown(lst));
end;

我让它在一个简单的示例中工作。

做类似的事情：

var
  l: TXList<TAClass>;
  i: TASubclassOfTAClass;
begin
.
.
.
for i in l.FindAll<TASubclassOfTAClass> do
begin
   // Do something with i
end;

Answer 1

通过三个小的修改（IInterface、带有“S：类”的 FindAll [感谢 Mason] 以及 FindAll 中的类型转换），我可以编译它。

完整代码：

unit Unit16;

interface

uses
  Generics.Collections;

type
  IXList<T> = interface
  end;

  TXList<T: class> = class(TList<T>, IInterface, IXList<T>)
  protected
    FRefCount: Integer;
    function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
    function _AddRef: Integer; stdcall;
    function _Release: Integer; stdcall;
  public
    function Find: IXList<T>;
    function FindAll<S: class>: IXList<S>;
  end;

implementation
uses Windows;

function TXList<T>.Find: IXList<T>;
begin
  Result := TXList<T>.Create;
end;

function TXList<T>.FindAll<S>: IXList<S>;
begin
  Result := IXList<S>(IUnknown(TXList<S>.Create));
end;

function TXList<T>.QueryInterface(const IID: TGUID; out Obj): HResult;
begin
  Result := E_NoInterface;
end;

function TXList<T>._AddRef: Integer;
begin
  InterlockedIncrement(FRefCount);
end;

function TXList<T>._Release: Integer;
begin
  InterlockedDecrement(FRefCount);
  if FRefCount = 0 then Self.Destroy;
end;

end.

Answer 2

这看起来绝对像是一个编译器错误。他们说他们如何投入大量精力来改进下一个版本 Delphi XE 的泛型问题。当它发布时（应该在接下来的几周内），下载预览版并查看现在是否可以编译。如果没有，请尝试向 QC 提交错误报告。

另外，FindAll 可能应该声明为 function FindAll: IXList;。这并不能解决错误，但是工作的编译器可能会给你一个错误。