VBA：如何搜索集合？

Question

我正在寻找集合中的特定元素。我如何知道它是否存在于集合中？

Answer 1

集合是基于索引的。因此，您必须循环遍历集合才能搜索项目。

Sub test()
Dim iCtr As Integer
Dim itemCount As Integer

Dim myData As Collection
Set myData = New Collection

Dim searchFor As String

myData.Add "MS", "11"
myData.Add "Oracle", "22"
myData.Add "Google", "33"

'** Searching based on value
searchFor = "Google"

itemCount = myData.Count
For iCtr = 1 To itemCount
    If myData(iCtr) = searchFor Then
        MsgBox myData(iCtr)
        Exit For
    End If
Next

'** Searching by key
MsgBox myData.Item("22")
End Sub

Answer 2

如果您在将项目添加到集合时使用了键，请查看引用此键是否会出现错误：

on error goto no_item
col.Item "key"
msgbox "Item exists"

exit sub

no_item:    
msgbox "Item does not exist"

否则，您必须循环遍历所有项目以查看是否有您需要的项目。

Answer 3

我使用一个简单的工具函数来迭代集合。它无需直接访问索引，而是使用 VBA 语言功能（变体比较和each-Loop）。

Public Function ExistsIn(item As Variant, lots As Collection) As Boolean
    Dim e As Variant
    ExistsIn = False
    For Each e In lots
        If item = e Then
            ExistsIn = True
            Exit For
        End If
    Next
End Function

Answer 4

@约书亚·施密德：

我认为您答案中的代码可能是正确的，但也可能不正确。您的函数具有 Variant 类型的参数，然后将其与集合中的每个成员进行比较。但实际上比较什么呢？在这种情况下，将比较默认成员。因此，如果集合包含某些未指定默认成员的自定义类的成员，则可能会出现第一个问题。在这种情况下，将引发运行时错误 438 对象不支持此属性或方法。好吧，您可以添加默认成员，但即便如此，恐怕它也会以您可能不喜欢的方式工作。

范围示例（范围类值是默认成员，因此将比较值）。也许这正是您想要的，但也许不是。因此，从我的角度来看，更好的方法是对添加到集合中的每个项目使用“Key”，然后尝试通过其 Key 获取该项目。

Debug.Print col.item(r1.Address) ' A1 值

如果没有使用键，则按索引：

Debug.Print col.item(1) ' A1 值

Sub test()
    Dim col As New VBA.Collection

    Dim r1 As Range
    Dim r2 As Range
    Dim r3 As Range

    Set r1 = Range("a1")
    Set r2 = Range("b1")
    Set r3 = Range("c1")

    r1 = "A1 Value"
    r2 = "B1 Value"
    r3 = "C1 Value"

    col.Add r1, r1.Address
    col.Add r2, r2.Address
    col.Add r3, r3.Address

    Debug.Print ExistsIn(r1, col)
    Debug.Print ExistsIn(r2, col)
    Debug.Print ExistsIn(r3, col)

    Dim r4 As Range
    Set r4 = Range("d1")
    r4 = "A1 Value"

    Debug.Print ExistsIn(r4, col)
End Sub

输出：

True
True
True
True

Answer 5

可以通过变体来确定集合项目。在下面的示例中，我确定 FXItems 集合中是否存在具有特定索引的对象。如果不存在，系统将创建它，否则执行其他操作

            On Error Resume Next
            Dim myFXItem as FXItem
            Set myFXItem = FXItems.item("USDEUR")
            On Error GoTo 0

            If myFXItem Is Nothing Then
                Set myFXItem = New FXItem
                myFXItem.sCurr = "USDEUR"
                FXItems.Add item:=myFXItem, Key:="USDEUR"
            Else
                myFXItem.dRate = 0.834
                myFXItem.dtValueDate = #12-03-2018#
            End If
            Set myFXItem = Nothing