Flex 3 中的 AdvancedDatagrid 排序

Question

我在 Flex 3 中使用 AdvancedDatagrid。AdvancedDatagrid 的一列包含数字和字母。当我对此列进行排序时，数字位于字母之前（AdvancedDatagrid 内部排序的默认行为）。但我希望排序时字母位于数字之前。

我知道我必须编写自定义排序函数。但任何人都可以给出一些关于如何进行的想法吗？

提前致谢。

Answer 1

使用 sortCompareFunction

AdvancedDataGrid 控件使用此函数对数据提供程序集合的元素进行排序。回调函数的函数签名有两个参数，格式如下：

mySortCompareFunction(obj1:Object, obj2:Object):int

obj1 — 要比较的数据元素。

obj2 — 与 obj1 进行比较的另一个数据元素。

该函数应根据对象的比较返回一个值：

• 如果 obj1 应按升序出现在 obj2 之前，则为 -1。
• 如果 obj1 = obj2，则为 0。
• 1 如果 obj1 应按升序出现在 obj2 之后。

<mx:AdvancedDataGridColumn sortCompareFunction="mySort" 
    dataField="colData"/>

尝试以下排序比较函数。

public function mySort(obj1:Object, obj2:Object):int
{
    var s1:String = obj1.colData;
    var s2:String = obj2.colData;
    var result:Number = s1.localeCompare(s2);
    if(result != 0)
        result = result > 0 ? 1 : -1;
    if(s1.match(/^\d/))
    {
        if(s2.match(/^\d/))
            return result;
        else
            return 1;
    }
    else if(s2.match(/^\d/))
        return -1;
    else 
        return result;
}

它检查字符串的第一个字符，并将以数字开头的字符按排序顺序向下推送。它使用 localeCompare 来比较两个字符串，如果它们都以字母或数字开头 - 否则它表示以字母开头的应该位于以数字开头的前面。因此，abc 将位于 123 之前，但 a12 仍将位于 abc 之前。

如果您想要一种完全不同的排序，其中字母始终位于数字之前，无论它们在字符串中的位置如何，您必须从头开始编写一个 - String::charCodeAt 可能是一个不错的起点。