在 OnExecute 事件中使用数据库 (Indy)

Question

我有一台带有这些代码的服务器：

procedure TFrmMain.TCPServerExecute(AContext: TIdContext);
begin
      Res := DoRegister(Name,Family,Username,Password);
end;

function TFrmMain.DoRegister(Name,Family,Username,Password:string): bool;
var
  Qry: TSQLQuery;
begin
  Qry := TSQLQuery.Create(nil);
  try
    Qry.SQLConnection := FrmConnect.SQLConnection;
    Qry.SQL.Text :='INSERT INTO `table` ...';
    Qry.ExecSQL();
  finally
    Qry.Free;
  end;
  Result := True;
end;

访问不同线程中的一个表是否有任何问题？在 Onexecute 事件中使用到底有什么危险？

谢谢朋友的回复。

那么，这是为不同线程建立不同连接的真正方法吗？

var
  Qry: TSQLQuery;
  SqlCon: TSQLConnection;
Begin
  SqlCon := TSQLConnection.Create(nil);
  Qry := TSQLQuery.Create(nil);
  try
    SqlCon := FrmConnect.SQLConnection;
    Qry.SQLConnection := SqlCon;
  finally
    SqlCon.Free;
    Qry.Free;
  end;
end;

Answer 1

您的第二个代码片段不正确。当您应该复制连接字符串时，您正在使用全局连接覆盖新连接。您还释放了该全局变量，这可能会导致应用程序的其余部分出现问题。像这样的事情，取决于 TSQLConnection 类的详细信息：

SqlCon := TSQLConnection.Create(nil); // create
Qry := TSQLQuery.Create(nil);
try
  //SqlCon := FrmConnect.SQLConnection; // overwrite!!!
  SqlCon.ConnectionString :=  FrmConnect.SQLConnection.ConnectionString;
  SqlCon.Active := true;
  Qry.SQLConnection := SqlCon;
  ...

如果您想要一个数据库连接池，这是相当棘手的，因为连接通常是特定于线程的 - 每个线程需要一个连接，并且不能在线程之间传递它们。所以你最终会编写大量代码来支持这一点。

我现在使用 OmniThreadLibrary 并有一个返回新数据库连接的工厂方法。这为我提供了一个线程池，我可以将任务输入其中，因此我的特定任务在执行时绑定到现有线程，但该线程的寿命相当长。我必须编写的代码非常小（我正在使用 ADO）：

type
    // a factory to generate new instances of our thread-specific data
    IThreadPoolData = interface
        ['{14917B01-6613-4737-B87E-0046789D4284}']
        function GetConnection: TADOConnection;
        function GetStoredProc: TADOStoredProc;
    end;

    TThreadPoolData = class(TInterfacedObject, IThreadPoolData)
    strict private
        FADOConnection: TADOConnection;
        FStoredProc: TADOStoredProc; // lazy creation!
    public
        constructor Create(aConnectionString: string); overload;
        destructor Destroy; override;
        function GetConnection: TADOConnection;
        function GetStoredProc: TADOStoredProc;
    end;

// create the connection here so thread creation is slow but using it 
// is (relatively) fast

constructor TThreadPoolData.Create(aConnectionString: string);
begin
    FADOConnection := TADOConnection.Create(nil);
    FADOConnection.LoginPrompt := false;
    FADOConnection.ConnectionString := aConnectionString;
    FADOConnection.ConnectOptions := coAsyncConnect;
    FADOConnection.Connected := true;
end;

destructor TThreadPoolData.Destroy;
begin
    FADOConnection.Connected := false;
    if assigned(FStoredProc) then
        FreeAndNil(FStoredProc);
    FreeAndNil(FADOConnection);
end;

如果您编写自己的线程或连接池，则需要执行类似的操作。

Answer 2

每个访问数据库的线程都应该有自己的连接，不能在多个线程之间共享数据库连接。 OnExecute 事件是在与请求客户端对应的线程上下文中调用的，因此每次调用它时，都会在工作线程内执行，并且这样的线程应该有自己的数据库连接。

如果不想为每个工作线程建立一个新的连接；一种选择可能是，您专用一个线程用于数据库连接，并将所有数据库操作委托给该线程，例如您的其他线程可以将其 INSERT SQL 语句发送到该数据库线程中的队列，并且该数据库线程执行它们 -使用单个数据库连接逐一。当然，如果您采用这种方法，所有数据库负载都将位于单个线程上，并且如果您有如此多的数据库操作，那么数据库线程本身可能会成为性能瓶颈！此外，采用这种方法，查询执行将是异步的，除非您在每个线程要求数据库线程为它们执行数据库查询时使用同步技术。

另请注意，如果您的数据库访问组件是 ADO，那么您必须调用 CoInitialize 和 CoUninitialize，因为 Delphi 运行时仅对主线程执行此操作，而不对您创建的其他线程执行此操作。

Answer 3

我会使用连接池来进行数据库连接。然后，每个线程仅在需要时从池中请求连接（如果池中当前没有空闲连接，则可能会阻塞），然后使用它并最终将其返回到池中。池的优点是所需的连接比并发线程少，并且在需要时连接已经存在。

Answer 4

是和不是。您可以从不同的线程访问单个表，但每个线程需要一个 TSQLConnection 实例才能安全地执行此操作。

更新

为每个线程实例化不同的连接就可以了。这也是大多数网页一直在做的事情（使用 asp、php 或 ... 的服务器端脚本意味着无状态执行，因此连接通常无法保留到下一个请求，必须重新建立）。

如果您担心开销，可以考虑使用 vcldeveloper 建议的单个连接。您必须确保该“连接线程”使用的由其他线程更改的任何变量和成员字段（例如接收要执行的 SQL 的字段成员）必须受到某种同步机制的保护。

这同样适用于 mjustin 建议的连接池，尽管在这种情况下，连接池需要受到同步机制的保护。