在 Perl 中将 UTF8 字符串转换为数值

Question

例如，

my $str = '中國c'; # Chinese language of china

我想打印出数值

20013,22283,99

Answer 1

unpack 比 split< 更高效/code> 和 ord，因为它不必生成一堆临时的 1 字符字符串：

use utf8;

my $str = '中國c'; # Chinese language of china

my @codepoints = unpack 'U*', $str;

print join(',', @codepoints) . "\n"; # prints 20013,22283,99

快速基准测试显示它比 split+ord 快大约 3 倍：

use utf8;
use Benchmark 'cmpthese';

my $str = '中國中國中國中國中國中國中國中國中國中國中國中國中國中國c';

cmpthese(0, {
  'unpack'     => sub { my @codepoints = unpack 'U*', $str; },
  'split-map'  => sub { my @codepoints = map { ord } split //, $str },
  'split-for'  => sub { my @cp; for my $c (split(//, $str)) { push @cp, ord($c) } },
  'split-for2' => sub { my $cp; for my $c (split(//, $str)) { $cp = ord($c) } },
});

结果：

               Rate  split-map  split-for split-for2     unpack
split-map   85423/s         --        -7%       -32%       -67%
split-for   91950/s         8%         --       -27%       -64%
split-for2 125550/s        47%        37%         --       -51%
unpack     256941/s       201%       179%       105%         --

字符串较短时，差异不太明显，但 unpack 的速度仍然快两倍以上。 （split-for2 比其他拆分要快一些，因为它不构建代码点列表。）

Answer 2

请参阅 perldoc -f ord：

foreach my $c (split(//, $str))
{
    print ord($c), "\n";
}

或压缩为一行：my @ chars = map { ord } split //, $str;

Data::Dumper ed，这会产生：

$VAR1 = [
          20013,
          22283,
          99
        ];

Answer 3

要让源代码中的 utf8 被识别，您必须事先使用 utf8; ：

$ perl
use utf8;
my $str = '中國c'; # Chinese language of china
foreach my $c (split(//, $str))
{
    print ord($c), "\n";
}
__END__
20013
22283
99

或者更简洁地说，

print join ',', map ord, split //, $str;

Answer 4

http://www.perl.com/pub/2012/04 /perlunicook-standard-preamble.html

#!/usr/bin/env perl


 use utf8;      # so literals and identifiers can be in UTF-8
 use v5.12;     # or later to get "unicode_strings" feature
 use strict;    # quote strings, declare variables
 use warnings;  # on by default
 use warnings  qw(FATAL utf8);    # fatalize encoding glitches
 use open      qw(:std :utf8);    # undeclared streams in UTF-8
 # use charnames qw(:full :short);  # unneeded in v5.16

# http://perldoc.perl.org/functions/sprintf.html
# vector flag
# This flag tells Perl to interpret the supplied string as a vector of integers, one for each character in the string. 

my $str = '中國c';

printf "%*vd\n", ",", $str;