如何用Perl将指定格式的数据写入二进制文件？

Question

这可能是一个相当新手的问题，但我需要处理某个文本文件并将其内容转储到二进制文件中，我不知道如何 - 我决定使用 perl，但我的 perl 技能相当低。我可能应该用 C++ 编写这个，但这对于 perl 来说似乎是一个很好且简单的任务，所以为什么不学习一些新的东西呢？ ;) 该文本文件有数千行，格式如下：

2A02FC42 4

您可以将其视为十六进制数字（长度始终 8）和常规数字。现在我需要将所有行转储到以下格式的二进制文件中（使用十六进制编辑器查看时应该如下所示）：

42FC022A00000004

更多示例，以便清楚：

70726F67 36< /代码> -> 676F727000000024
6A656374 471 -> 7463656A000001D7


解析输入文件的部分很简单，但我陷入了第二部分，我应该将其写入二进制文件。我不知道如何以这种方式格式化数据，甚至不知道如何以二进制模式输出内容。有人可以帮我吗？

谢谢。

编辑：更新了示例，忘记了字节序 - 我在 LE 系统上。

Answer 1

使用 pack：

#! /usr/bin/perl

use warnings;
use strict;

# demo only    
*ARGV = *DATA;

while (<>) {
  my($a,$b) = split;
  $a = join "", reverse $a =~ /(..)/g;
  $b = sprintf "%08x", $b;

  print pack "H*" => $a . $b;
}

__DATA__
2A02FC42 4
70726F67 36
6A656374 471

示例运行：

$ ./prog.pl | od -t x1
0000000 42 fc 02 2a 00 00 00 04 67 6f 72 70 00 00 00 24
0000020 74 63 65 6a 00 00 01 d7
0000030

Answer 2

我的版本（已测试）：

my $fout;
if ( ! open( $fout, ">/tmp/deleteme.bin" ) ) {
    die( "Failed to open /tmp/deleteme.bin: $!" );
}
binmode( $fout );

while ( <DATA> ) {
    my ( $left, $right ) = split( /\s+/s, $_ );

    my $output = pack( "VN", hex($left), int($right) );
    printf(
        STDERR
        "  note, %8X %d -> " . ( "%02X" x 8 ) . "\n",
        hex($left), $right,
        map { $_ } unpack( "C8", $output )
    );

    print( $fout $output );
}
close( $fout );

__DATA__
70726F67 36 -> 676F727000000024
6A656374 471 -> 7463656A000001D7

输出：

note, 70726F67 36 -> 676F727000000024
note, 6A656374 471 -> 7463656A000001D7

Answer 3

规范的方法是使用 pack。假设您从文本文件中读取的数据已转换为数字（包括十六进制），并存储在变量 $x 和 $y 中。那么你应该做类似的事情

 print OUTFILE pack("NN", $x, $y);

如果你需要不同的字节顺序，你将不得不使用
与 NN 不同的模板，请参阅 perldoc -f pack 了解详细信息。