Perl：为什么这会创建数千个子进程？

Question

所以当我运行这段代码时，它似乎对系统进行了分叉炸弹，你们能帮我吗？我想要做的就是为每个 appWatch 域和环境启动一个线程。

#!/usr/bin/perl
#
#
#       Starts the mass processes to watch each directory & enviroment.
#
#
#
###################################################################################
use strict;
use warnings;
use POSIX 'setsid';
setsid();
my @domains = (qw(austin batman luke heman drevil joker skeltor drevil goodguy badguy));
my @envs = (qw(qa dev));
        foreach my $env (@envs){
                foreach my $guy (@domains){
                        unless(my $pid = fork()){
                                system("echo $env.$guy");
                                system("sleep 10 ");
                                #system("./appWatch -d $guy -e $env");
                                open PID, ">>pid.lock";
                                print PID $$ . "\n";
                                print "$$ is Parent, $pid is child";
                }
        }
}
                wait();

Answer 1

您的代码应该只创建三个子级。如果您看到创建了一堆子项，那么您正在运行不同的代码（或者罪魁祸首是 appWatch 而不是您的代码）。稍微不相关的一点是，有几件事您可能应该采取不同的做法：

1. fork 有三个可能的返回值，而不是两个，
2. 您必须收获您的孩子或设置系统为您收获
3. 它们应该使用 exec 而不是 system 如果您不想返回代码，
4. 则应该使用 system 和 exec 的多参数版本如果您不希望 shell 对参数执行某些操作，请选择单参数版本。

这是我的代码版本：

$SIG{CHLD}  = "IGNORE"; #auto-reap the children
my @domains = qw(domains);
my @envs    = qw(enviromentA enviromentB);
for my $env (@envs){
        for my $guy (@domains){
                die "could not fork: $!" unless defined(my $pid = fork);
                next if $pid;
                exec "./appWatch", "-d", $guy, "-e", $env;
                die "exec must have failed";
        }
}

您更新的代码版本显示了发生了什么。您的孩子不会退出。这是我编写代码的方式：

#!/usr/bin/perl
# Starts the mass processes to watch each directory & enviroment.

use strict;
use warnings;
use POSIX 'setsid';
setsid();

my @domains = qw(
    austin  batman luke    heman
    drevil  joker  skeltor drevil
    goodguy badguy
);
my @envs = qw(qa dev);

my @pids;
for my $env (@envs){
    for my $guy (@domains){
        die "could not fork: $!" unless defined(my $pid = fork);
        if ($pid) {
            push @pids, $pid;
            next;
        }
        print "$env.$guy\n";
        sleep 10; #FIXME: I don't know if you really need this
        #exec will replace the child process with appWatch
        exec "./appWatch", "-d", $guy, "-e", $env;
        die "exec failed for some reason";
    }
}
for my $pid (@pids) {
    waitpid $pid, 0;
}

Answer 2

后

$ cat appWatch 
#! /usr/bin/perl -l
print "[", join("][" => @ARGV), "]";

运行

$ uname -a
Linux mybox 2.6.32-24-generic #39-Ubuntu SMP Wed Jul 28 05:14:15 UTC 2010 x86_64 GNU/Linux

，我没有得到 fork 炸弹，只是一个令人兴奋的笛卡尔积：

$ ./prog.pl 
[-d][domains][-e][enviromentA]
[-d][domains][-e][enviromentB]