求 Mathematica 中积分定义的函数的最小值

Question

我需要找到函数 f(t) = int g(t,x) dx 在 [0,1] 上的最小值。我在mathematica中所做的如下：

f[t_] = NIntegrate[g[t,x],{x,-1,1}]
FindMinimum[f[t],{t,t0}]

然而mathematica在第一次尝试时就停止了，因为NIntegrate不支持符号t。它需要一个特定的值来评估。尽管 Plot[f[t],{t,0,1}] 工作正常，但 FindMinimum 停在初始点.

我不能用 Integrate 替换 NIntegrate，因为函数 g 有点复杂，如果你输入 Integrate，mathematica 就会继续运行......

有什么方法可以解决它吗？谢谢！

Answer 1

试试这个：

In[58]:= g[t_, x_] := t^3 - t + x^2

In[59]:= f[t_?NumericQ] := NIntegrate[g[t, x], {x, -1, 1}]

In[60]:= FindMinimum[f[t], {t, 1}]

Out[60]= {-0.103134, {t -> 0.57735}}

In[61]:= Plot[f[t], {t, 0, 1}]

我对您的代码做了两个相关更改：

1. 使用 := 定义 f，而不是使用 =。当 f 的用户提供了参数的值时，这有效地给出了 f“稍后”的定义。请参阅 SetDelayed。

2. 用t_?NumericQ而不是t_定义f。这表示，t 可以是任何数字（Pi、7、0 等）。但不是任何非数字（t、x、“foo”等）。

Answer 2

一点分析...

只要 Mathematica 可以对 g[t,x] 对 x 进行符号积分，您就可以获得精确答案，并完全避免数值积分的繁重工作，然后符号微分 wrtt 一个不那么简单的例子，具有更复杂的 g[t,x]，包括 x 和 t 中的多项式积：

g[t_, x_] := t^2 + (7*t*x - (x^3)/13)^2;
xMax = 1; xMin = -1; f[t_?NumericQ] := NIntegrate[g[t, x], {x, xMin, xMax}];
tMin = 0; tMax = 1;Plot[f[t], {t, tMin, tMax}];
tNumericAtMin = t /. FindMinimum[f[t], {t, tMax}][[2]];
dig[t_, x_] := D[Integrate[g[t, x], x], t];
Print["Differentiated integral is ", dig[t, x]];
digAtXMax = dig[t, x] /. x -> xMax; digAtXMin = dig[t, x] /. x -> xMin;
tSymbolicAtMin = Resolve[digAtXMax - digAtXMin == 0 && tMin ≤ t ≤ tMax, {t}];
Print["Exact: ", tSymbolicAtMin[[2]]];
Print["Numeric: ", tNumericAtMin];
Print["Difference: ", tSymbolicAtMin [[2]] - tNumericAtMin // N];

结果：

⁃Graphics⁃
Differentiated integral is 2 t x + 98 t x^3 / 3 - 14 x^5 / 65
Exact: 21/3380
Numeric: 0.00621302
Difference: -3.01143 x 10^-9

Answer 3

函数的最小值只能在其导数的零点处，那么为什么首先要积分呢？

• 您可以使用FindRoot或Solve来查找g的根
• 然后您可以通过检查g的导数来验证点是否确实是局部最小值 （此时应该是积极的）。
• 然后您可以NIntegrate 找到f 的最小值 - 只需一次数值积分！