在 perl 中打开管道时直接 STDERR

Question

我正在使用 open( my $command_out, "-|", $command_string ) 来执行命令并即时处理其输出（不必先等待命令完成，如 <代码>系统（））。

我注意到，当我以这种方式调用一些 R 脚本时，一些 R 消息会打印到屏幕上（例如 正在加载所需的包：...）。我猜这是因为 R 将此输出发送到 stderr （？尽管这些并不是真正的错误）。

当 open() 时，是否可以将此输出也定向到 $command_out 以便屏幕保持干净？

Answer 1

假设您的 R 程序结果

#! /usr/bin/env r

require(Hmisc)

cat(argv[1], "\n")

出人意料地喋喋不休：

$ ./prog.r foo
Loading required package: Hmisc
Loading required package: methods
Loading required package: survival
Loading required package: stats
Loading required package: utils
Loading required package: graphics
Loading required package: splines

Attaching package: 'Hmisc'


    The following object(s) are masked from package:survival :

     untangle.specials 


    The following object(s) are masked from package:base :

     format.pval,
     round.POSIXt,
     trunc.POSIXt,
     units 

foo

从这里，您可以丢弃标准错误或将其与另一个流合并。

丢弃标准错误

丢弃标准错误的一种方法是使用 shell 重定向 2>/dev/null。这是一个通用机制，2 是标准错误的文件描述符。例如：

#! /usr/bin/perl

use warnings;
use strict;

open my $command_out, "-|", "./prog.r foo 2>/dev/null"
  or die "$0: could not start prog.r";

while (<$command_out>) {
  print "got: $_";
}

shell 还将处理 反引号或 qx// 表达式

#! /usr/bin/perl

use warnings;
use strict;

(my $command_out = `./prog.r foo 2>/dev/null`) =~ s/^/got: /mg;
print $command_out;

和标量命令传递给 system

#! /usr/bin/perl

use warnings;
use strict;

system("./prog.r foo 2>/dev/null") == 0
  or warn "$0: prog.r exited " . ($? >>8);

对于所有这些，输出为

$ ./prog.pl 
got: foo

但有时您不希望 shell 将其肮脏的手套放在您的命令上。也许它包含您不想处理转义的 shell 元字符或引号。这是安全管道打开有用的时候：

#! /usr/bin/perl

use warnings;
use strict;

my $pid = open my $command_out, "-|";
die "$0: fork: $!" unless defined $pid;

if ($pid == 0) {
  # child
  open STDERR, ">", "/dev/null" or die "$0: open: $!";
  exec "./prog.r", "foo & bar"  or exit 1;  # STDERR silent now
}

while (<$command_out>) {
  print "got: $_";
}

close $command_out or warn "$0: prog.r exited " . ($? >> 8);

打开"-|" 分叉一个子进程并将子进程的标准输出连接到该句柄。与 fork 一样，它向子进程返回 0，一个非-父进程的零进程标识符，或失败时的未定义值。

在子进程中，我们首先将 STDERR 重定向到 /dev/null，然后使用 exec 将子程序替换为我们的 R 程序。请注意，我们以列表形式传递命令来绕过 shell：

如果 LIST 中有多个参数，或者 LIST 是一个具有多个值的数组，则调用 execvp(3) 以及 LIST 中的参数。

因为我们无法再看到标准错误，所以显式关闭 $command_out 以检查子进程是否运行愉快非常重要。否则，您会遇到令人费解的无声失败。

示例运行：

$ ./prog.pl 
got: foo & bar

将 STDERR 合并到 STDOUT

要查看句柄上的标准错误，请改用 2>&1，eg< /em>，

open my $command_out, "-|", "./prog.r foo 2>&1" or die;

通过安全的管道打开，dup 将标准错误输出到标准输出：

if ($pid == 0) {
  # child
  open STDERR, ">&", \*STDOUT  or die "$0: open: $!";
  exec "./prog.r", "foo & bar" or die "$0: exec: $!";
}

open 文档涵盖了这一点：

您还可以按照 Bourne shell 传统，指定以 >& 开头的 EXPR，在这种情况下，字符串的其余部分将被解释为文件句柄（或文件描述符）的名称，如果是数字）被欺骗（如 dup(2)）并且打开。

尽管您可以通过这种方式看到标准错误，但使用 close 检查子进程的退出状态仍然是一个好主意。

现在一切都通过$command_out到达：

got: Loading required package: Hmisc
got: Loading required package: methods
got: Loading required package: survival
got: Loading required package: stats
got: Loading required package: utils
got: Loading required package: graphics
got: Loading required package: splines
got: 
got: Attaching package: 'Hmisc'
got: 
got: 
got:    The following object(s) are masked from package:survival :
got: 
got:     untangle.specials 
got: 
got: 
got:    The following object(s) are masked from package:base :
got: 
got:     format.pval,
got:     round.POSIXt,
got:     trunc.POSIXt,
got:     units 
got: 
got: foo & bar

Answer 2

一个简单的方法是将 2>&1 附加到 $command_string，但这是否有效取决于您的 shell。 （例如，解释 $command_string 的 shell）

Answer 3

使用 IPC::Run 分别捕获 STDOUT 和 STDERR。 pump 函数为您提供即时输出。

Answer 4

也许您可以将整个程序的 STDERR 重定向到 STDOUT ？

*STDERR = *STDOUT;
open( my $command.... );

Answer 5

做叉子和执行自己：

pipe R, W; # note: R and W have CLOEXEC set
if (fork == 0) {
    # child #
    open STDERR, '>&W';
    exec qw/ls -lrtac/, $ARGV[0];
    die 'not reached';
}
# parent #
close W;
while (<R>) { do_something }
close R;
wait;

}