如何在 Inno 设置中更改鼠标光标？

Question

我使用 Inno 安装程序创建了一个安装程序，在安装过程中，我进行了一些冗长的操作来检查系统上的某些值（注册表项、一些文件...），在此期间没有向用户显示任何界面，我执行了所有操作这在InitializeSetup函数中。

我想知道的是，在进行所有这些检查时是否可以更改鼠标指针，以便用户知道正在发生某些事情。

我想我可以创建一个dll并从inno调用dll内的函数来更改光标，但我不想制作一个单独的dll，我在想是否有一种方法可以仅使用pascal脚本来做到这一点。

感谢您的帮助。

Answer 1

也许 Inno Setup 的最新版本中发生了一些变化，但我无法从 Mirtheil 那里得到答案来工作。

相反，我想出了这个：

procedure SetControlCursor(oCtrl: TControl; oCurs: TCursor);
var 
  i     : Integer;
  oCmp  : TComponent;
begin
  oCtrl.Cursor := oCurs;
  for i := 0 to oCtrl.ComponentCount-1 do
  begin
    oCmp := oCtrl.Components[i];
    if oCmp is TControl then
    begin
      SetControlCursor(TControl(oCmp), oCurs);
    end;
  end;
end;

设置沙漏光标：

SetControlCursor(WizardForm, crHourGlass);    

重置沙漏光标：

SetControlCursor(WizardForm, crDefault);  

希望这对某人有帮助！

Answer 2

取自： http://www.vincenzo.net/isxkb/index.php?title=Cursor_-_Change_the_mouse_cursor_of_WizardForm

procedure SetControlCursor(control: TWinControl; cursor: TCursor);
var i:Integer;
    wc: TWinControl;
begin
  if (not (control = nil)) then begin
    control.Cursor := cursor;
    try
      for i:=0 to control.ControlCount-1 do begin
        wc := TWinControl(control.Controls[i]);
        if (NOT(wc = nil)) then
          SetControlCursor(wc, cursor)
        else
          control.Controls[i].Cursor := cursor;
      end; {for}
    finally

    end;{try}
  end;{if}
end;{procedure SetControlCursor}

并将其设置为沙漏：

SetControlCursor(WizardForm, crHourGlass);

将其设置回正常状态：

SetControlCursor(WizardForm, crDefault);

Answer 3

结合 @mirtheil 和 @Sirp 的答案中的好部分，这是我认为的最佳解决方案：

procedure SetControlCursor(Control: TControl; Cursor: TCursor);
var 
  I: Integer;
begin
  Control.Cursor := Cursor;
  if Control is TWinControl then
  begin
    for I := 0 to TWinControl(Control).ControlCount - 1 do
    begin
      SetControlCursor(TWinControl(Control).Controls[I], Cursor);
    end;
  end;
end;

设置沙漏光标：

SetControlCursor(WizardForm, crHourGlass);    

重置默认光标：

SetControlCursor(WizardForm, crDefault);