如何创建多变量 Haskell 函数？

Question

我需要一个函数，它接受任意数量的参数（全部相同类型），对它们执行某些操作，然后返回结果。在我的具体情况下，列出参数是不切实际的。

当我查看 haskell 库时，我发现函数 printf（来自模块 Text.Printf）使用了类似的技巧。不幸的是，我无法通过查看源代码来理解这种魔力。

有人可以解释如何实现这一点，或者至少在一些网页/论文/任何我可以找到对此的良好描述的地方吗？

动机：

我需要这个的原因非常简单。对于学校（计算机科学课），我们需要编写一个能够“记录”数学表达式的模块，将其表达为字符串（通过为自己的数据类型编写 Num/Real/etc 的实例），并执行对其进行各种操作。

此数据类型包含变量的特殊构造函数，可以用指定函数的值或其他内容替换该变量。目标之一是编写一个函数，该函数采用带有一定数量变量（(Char,Rational) 类型对）的表达式并计算表达式的结果。我们应该看看如何最好地表达函数的目标。 （我的想法：该函数返回另一个函数，该函数接受与函数中定义的变量完全相同的参数 - 似乎是不可能的）。

Answer 1

KennyTM 的回答很棒。下面以 sumOf 1 4 7 10 :: Integer 的执行过程为例来更好地说明。

sumOf 1 4 7 10
(( \ x -> ( sumOf . (x +) . toInteger ) 1 ) 4 7 10
((sumOf . (1 + ) . toInteger) 4 ) 7 10
( sumOf 5 ) 7 10
( sumOf . (5 + ) . toInteger ) 7 10
sumOf 12 10
sumOf . (12 + ) . toInteger 10
sumof 22
id 22
22

Answer 2

很多人告诉你如何创建可变参数函数，但我认为在这种情况下，你实际上最好只使用 [(Char,Rational)] 类型的列表。

Answer 3

在有关可变参数函数的 wiki 文章中，引用了这篇文章。我想这就是 printf 所做的，但我也不明白。无论如何，这肯定是一种矫枉过正，特别是因为你的论点都是同一类型。只需将它们全部放在一个列表中即可。这就是列表的好处——任意数量的相同类型的事物。好吧，它不是很漂亮，但它不会比完整的多变量函数更难看。

Answer 4

我查看了 delnan 引用的文章中链接的示例。盯着它看了一会儿之后，我想我终于明白了发生了什么：

它从这个类型类开始：

class BuildList a r  | r-> a where
    build' :: [a] -> a -> r

管道（|）后面的那一位是函数依赖。它表示可以通过r 表示的类型来确定a 表示的类型。换句话说，您无法定义具有相同 r（返回类型）但不同 a 的 BuildList 类型类的两个实例。

跳转到 build' 函数实际使用的地方：

> build True :: [Bool]

因为 build 只是调用 build' 并将空列表作为第一个参数，这与：

> build' [] True :: [Bool]

在此示例中，build' 显然返回一个列表。由于功能依赖性，我们只能绑定到 BuildList 类型类的此实例：

instance BuildList a [a] where
    build' l x = reverse$ x:l

非常简单。第二个例子更有趣。扩展build的定义，它变成：

> build' [] True False :: [Bool]

在这种情况下build'的类型是什么？好吧，Haskell 的优先规则意味着上面的内容也可以这样写：

> (build' [] True) False :: [Bool]

现在很明显，我们将两个参数传递给 build'，然后将该表达式的结果应用到一个参数值为“假”。换句话说，表达式 (build' [] True) 预计会返回 Bool -> 类型的函数。 [布尔]。这将我们绑定到 BuildList 类型类的第二个实例：

instance BuildList a r => BuildList a (a->r) where
    build' l x y = build'(x:l) y

在此调用中，l = [] 和 x = True 和 y = False，因此定义扩展为 build' [True] False :: [Bool]。该签名绑定到 build' 的第一个实例，并且从那里开始的走向相当明显。

Answer 5

printf 的关键点是能够返回字符串或函数。复制自 http ://www.haskell.org/ghc/docs/6.12.2/html/libraries/base-4.2.0.1/src/Text-Printf.html，

printf :: (PrintfType r) => String -> r
printf fmts = spr fmts []

class PrintfType t where
    spr :: String -> [UPrintf] -> t

instance (IsChar c) => PrintfType [c] where
    spr fmts args = map fromChar (uprintf fmts (reverse args))

instance (PrintfArg a, PrintfType r) => PrintfType (a -> r) where
    spr fmts args = \a -> spr fmts (toUPrintf a : args)

我们可以提取出的基本结构是

variadicFunction :: VariadicReturnClass r => RequiredArgs -> r
variadicFunction reqArgs = variadicImpl reqArgs mempty

class VariadicReturnClass r where
   variadicImpl :: RequiredArgs -> AccumulatingType -> r

instance VariadicReturnClass ActualReturnType where
   variadicImpl reqArgs acc = constructActualResult reqArgs acc

instance (ArgClass a, VariadicReturnClass r) => VariadicReturnClass (a -> r) where
   variadicImpl reqArgs acc = \a -> variadicImpl reqArgs (specialize a `mappend` acc)

例如:

class SumRes r where 
    sumOf :: Integer -> r

instance SumRes Integer where
    sumOf = id

instance (Integral a, SumRes r) => SumRes (a -> r) where
    sumOf x = sumOf . (x +) . toInteger

那么我们可以使用

*Main> sumOf 1 :: Integer
1
*Main> sumOf 1 4 7 10 :: Integer
22
*Main> sumOf 1 4 7 10 0 0  :: Integer
22
*Main> sumOf 1 4 7 10 2 5 8 22 :: Integer
59