AS3：Singleton 类与 LocalConnection 类

Question

我有一个加载 2 SWF 的主类（加载器和查看器，还包含文档类）。他们需要与内容共享一个双缓冲区，当然，由加载器填充并由查看器显示

我正在考虑使用 LocalConnection 类，但在 PatrickS 的建议后，现在我正在评估 Singleton 类的可能性。我从未在 AS 中使用过这种模式，并且必须承认我对它有相当的偏见。但在这种特殊情况下，我想它会很有用。顺便说一下，阅读 gskinner 博客中的 2 个实现示例有点惊讶。所以，我真的很欣赏你的观点，因为我知道这个主题是一场无休止的战争，就像 Mac 与 PC 之间的战争一样，

考虑到： 1. AIR 桌面应用程序在高端 Windows PC 上连续几个月 24x7 运行。无用户交互 2.高性能代码是必须的，因为加载的内容是全高清图像

我的另一个担忧是内存泄漏

提前致谢

Answer 1

就我个人而言，我会避免使用 Singleton，因为它会定期实现。但是，拥有此缓冲区对象的单个实例是有意义的。所以在这种情况下我要做的是让你的 Main 类创建这个对象。当查看器加载时，将这个对象传递给它。然后对装载机执行相同的操作。现在，您的两个 swf 共享一个可用于通信的公共对象。然后，您可以在其上调用函数并根据需要使其调度事件（扩展 EventDispatcher 或实现 IEventDispatcher）。或者，您可以根据需要注册回调（应该会快一点，但不确定是否会产生很大的影响）。

编辑

看看您的其他问题，我认为您的问题与获取正确的加载器并将数据传递到加载的内容有关。以下是如何实现我上面提到的内容的概述。

PhotoLoader.swf:

package  {
import flash.display.Sprite;
import flash.events.Event;

public class PhotoLoader extends Sprite {

    private var _commonObject:CommonObject;

    public function PhotoLoader() {

    }

    public function setCommonObject(commonObject:CommonObject):void {
        trace("PhotoLoader::setCommonObject", commonObject);
        _commonObject = commonObject;
        _commonObject.addEventListener(Event.INIT,handleInit);
    }

    private function handleInit(e:Event):void {
        trace("PhotoLoader::handleInit");
    }

}

} 

PhotoViewer.swf:

package  {
    import flash.display.Sprite;
    import flash.events.Event;

    public class PhotoViewer extends Sprite {

        private var _commonObject:CommonObject;

        public function PhotoViewer() {

        }

        public function setCommonObject(commonObject:CommonObject):void {
            trace("PhotoLoader::setCommonObject", commonObject);
            _commonObject = commonObject;
            _commonObject.addEventListener(Event.INIT,handleInit);
        }

        private function handleInit(e:Event):void {
            trace("PhotoViewer::handleInit");
        }

    }

}

Main.swf

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLRequest;
    import flash.system.ApplicationDomain;
    import flash.system.LoaderContext;

    public class Main extends Sprite {

        private var _photoLoader:PhotoLoader;
        private var _photoViewer:PhotoViewer;
        private var _commonObject:CommonObject;

        private var _viewerLoader:Loader;
        private var _loaderLoader:Loader;

        private var _count:int = 0;

        public function Main():void {
            _commonObject = new CommonObject();
            loadSwfs();

        }

        private function loadSwfs():void {

            _viewerLoader = new Loader();
            _viewerLoader.contentLoaderInfo.addEventListener(Event.INIT,handleInit);
            _viewerLoader.load(new URLRequest("PhotoViewer.swf"));

            _loaderLoader = new Loader();
            _loaderLoader.contentLoaderInfo.addEventListener(Event.INIT,handleInit);
            _loaderLoader.load(new URLRequest("PhotoLoader.swf"));

        }

        private function handleInit(e:Event):void {
            trace("handleInit");
            var loader:Loader = (e.target as LoaderInfo).loader;
            switch(loader) {
                case _viewerLoader:
                    _photoViewer = _viewerLoader.content as PhotoViewer; 
                    _photoViewer.setCommonObject(_commonObject);
                    _count++;
                    break;
                case _loaderLoader:
                    _photoLoader = _loaderLoader.content as PhotoLoader; 
                    _photoLoader.setCommonObject(_commonObject);
                    _count++;
                    break;
            }
            if(_count == 2) { 
                _commonObject.init();
            }

        }


    }

}

以及由 3 个 swf 共享的公共对象：

package  {
    import flash.events.Event;
    import flash.events.EventDispatcher;

    public class CommonObject extends EventDispatcher {

        public function CommonObject() {

        }

        public function init():void {
            dispatchEvent(new Event(Event.INIT));
        }
    }

}

基本上，当您加载查看器和加载器 swf 时，您会传递此公共对象的一个​​实例。然后您注册监听 INIT 方法：这将告诉加载器和查看器一切都已设置完毕。因此，此时您可以开始从查看器或加载器向另一方发送消息（您可以通过事件调度来实现这一点）；基本上在公共对象中创建一个方法来为您执行此操作，或者直接在公共对象上调用dispatchEvent。