我有一个 AS3 类，它用动态图像扩展 movieClip，如何使该图像可拖动？

Question

我需要使一个项目可拖动（可拖动？）抱歉，如果我的术语不正确！

我有一个类，我将在其中存储变量并进行计算：

package Classes
{
    import flash.display.*;
    import flash.events.*;
    import flash.net.*;

    public class PrintItem extends MovieClip
    {     
        public var imageLoader:Loader;

        public function PrintItem()
        {

        }

        public function loadImage(url:String):void
        {
            imageLoader = new Loader();
            imageLoader.load(new URLRequest(url));
        }
    }
} 

我创建该类的一个新实例，在 loadImage 中向它传递一个 URL，然后将其添加到画布中，如下所示：

var myItem:PrintItem = new PrintItem();
myItem.loadImage("pic.jpg");
this.addChild(myItem.imageLoader);
myItem.imageLoader.x = 50;
myItem.imageLoader.y = 50;
myItem.imageLoader.addEventListener(MouseEvent.MOUSE_DOWN, pickUp);
myItem.imageLoader.addEventListener(MouseEvent.MOUSE_UP, dropIt);

但我被困住了。我需要使该项目可拖动并编写 pickUp 和 dropIt 函数。 event.target.startDrag(false);不起作用（Loader 不可拖动）和 event.target.parent.startDrag(false);不起作用，因为整个舞台变得可拖动！帮助！是因为舞台上只添加了Loader吗？

Answer 1

好的。我知道这只是几分钟，但我已经找到了答案。把它写在这里，我的脑子里就清楚了。这是对我有用的方法，以防对其他人有帮助：

首先，我将加载器图像作为子项添加到类中，如下所示：

public function loadImage(url:String):void
{
    imageLoader = new Loader();
    imageLoader.load(new URLRequest(url));
    this.addChild(imageLoader); // IMPORTANT!
    this.mouseChildren = false;
    this.addEventListener(MouseEvent.MOUSE_DOWN, pickUp);
    this.addEventListener(MouseEvent.MOUSE_UP, dropIt);
}

然后我只需将类添加到舞台，而不是加载器：

this.addChild(myItem);

回到类，我添加了这个：

public function pickUp(event:MouseEvent):void
{
  trace("Pickup");
  this.startDrag(false);
}
public function dropIt(event:MouseEvent):void
{
  this.stopDrag();
  trace("X = " + event.target.x + " Y = " + event.target.y); // Just to help me
}

等等瞧！成功了！