经典 ASP：查询字符串处理程序

Question

我很久以前就做过了，现在找不到这个功能了。它不应该太复杂，但我想知道在我再次执行此操作之前是否有任何新闻...

采取这个：

www.example.com?query=whatever&page=1

现在想象我按按钮到第 2 页，它将变成：

www.example.com?query=whatever&page=2

始终保留查询字符串的其余部分完好无损的。现在第 2 页上的图片 我按下按钮按日期排序，它应该变成：

www.example.com?query=whatever&page=1&order=date

问题是，在用于排序的 ASP 代码上，我不想处理所有其他查询字符串。因此，我需要一个函数来为我处理它，并且能够执行类似以下示例的操作：

<a href="?<%= add_querystring(qs, "order", "date") %>">date</a>
<a href="?<%= set_querystring(qs, "page", page + 1) %>">next page</a>
<a href="?<%= add_querystring(del_querystring(qs, "page"), "allpages") %>">all pages</a>

这只是如果我仍然找不到现成的解决方案，我将要做什么的初步想法......再说一次，只是想知道是否有任何新的东西可以以我还没有想象到的方式来处理这一切。

Answer 1

如果有人感兴趣，这是我昨天滚动的相当混乱的代码：

'Build a string QueryString from the array Request
function bdl_qs (req_qs)
    dim result, qa, item
    result = empty
    qa = "?"
    if isnull(req_qs) or isempty(req_qs) then req_qs = Request.QueryString
    for each item in req_qs
        result = result & qa & item
        result = result & "=" & req_qs(item)
        qa = "&"
    next
    bdl_qs = result
end function

'Build a string QueryString ontop of the supplied one, adding the query and / or value(s) to it
function add_qs (qs, q, s)
    dim result
    result = qs
    if left(result, 1) = "?" then
        result = result & "&" & q
    else
        result = "?" & q
    end if
    if not isnull(s) and not isempty(s) then 
        result = result & "=" & s
    end if  
    add_qs = result
end function

'Build a string QueryString ontop of the supplied one, removing the selected query and / or values
function del_qs (qs, q)
    dim result, item
    result = qs
    if left(qs, 1) = "?" then
        dim rqs, qa
        rqs = result
        result = "?"
        rqs = right(rqs, len(rqs)-1) 'remove the "?"
        rqs = Split(rqs, "&") 'separate the queries
        qa = ""
        for each item in rqs
            dim rq
            rq = Split(item, "=") 'separate the query to analyze the name only
            if rq(0) <> q then 'good for rebuilding
                result = result & qa & item
                qa = "&"
            end if
        next
    end if
    del_qs = result
end function

'Build a string QueryString ontop of the supplied one, setting the query to the value
function set_qs (qs, q, s)
    set_qs = add_qs(del_qs(qs, q), q, s)
end function