SAS 中的 Access Crosstab 查询等效吗？

Question

这是我的输入：

ID  Color
1   green
1   red
1   orange
1   green
1   red
2   red
2   red
2   blue
3   green
3   red

这是我想要的输出 - 按 ID 为每种颜色列出的记录计数：

ID  green  red  orange blue
1   2      2    1      0
2   0      2    0      1
3   1      1    0      0

我知道我可以使用 proc freq 获取信息，但我想输出一个与我上面编写的数据集完全相同的数据集。我似乎无法弄清楚如何使颜色成为此输出数据集中的列。

Answer 1

首先，生成数据。

data data;
    format ID 8. Color $8.;
    input id color;
datalines;
1   green
1   red
1   orange
1   green
1   red
2   red
2   red
2   blue
3   green
3   red
run;

接下来，按 id 汇总颜色计数。

proc freq data=data noprint;
    table id*color / out=freq;
run;

把桌子弄平。

proc transpose data=freq out=freq_trans(drop=_:);
    id color;
    by id;
    var count;
run;

（可选）用 0 填充缺失的单元格。

data freq_trans_filled;
    set freq_trans;
    array c(*) green red orange blue;
    do i = 1 to dim(c);
        if c[i]=. then c[i]=0;
    end;
    drop i;
run;

Answer 2

您可以使用 PROC FREQ 的 TABLE 语句的 SPARSE 选项用零填充缺失的单元格。这样，您就不需要另一个 DATA 步骤。颜色的顺序也可以通过 PROC FREQ 的 ORDER= 选项来控制。

data one;
  input id color :$8.;
datalines;
1   green
1   red
1   orange
1   green
1   red
2   red
2   red
2   blue
3   green
3   red
run;
proc freq data=one noprint order=data;
  table id*color /out=freq sparse;
run;
proc transpose data=freq out=two(drop=_:);
    id color;
    by id;
    var count;
run;
proc print data=two noobs;
run;
/* on lst
id    green    red    orange    blue
 1      2       2        1        0
 2      0       2        0        1
 3      1       1        0        0
*/

Answer 3

我从来都不喜欢 proc transpose，因为我永远记不住语法。这是一种使用 proc sql 和宏变量来完成此操作的方法。

proc sql noprint;  
    select    sum(color = '" || trim(color) || "') as " || color into: color_list separated by ", "
    from      (select distinct color from one);  
    create table result as  
    select    id,  
              &color_list  
    from      one  
    group by  id;  
quit;



id            blue        green         orange            red  
1              0              2              1              2  
2              1              0              0              2  
3              0              1              0              1  

Answer 4

对于（pteranodon），我碰巧正在审查档案（6年多后），这就是为什么这么不合时宜，但有人可能会受益。

    proc sql noprint feedback;  
     select    catx(' ','sum(color =',quote(trim(color)),') as',color) into: color_list separated by ", "
       from (select distinct color from one);  
     create table result as  
      select id, &color_list  
      from one 
      group by id;  
    quit;