Haskell 中过度使用 fromIntegral

Question

每当我使用双精度和整数编写函数时，我都会发现这个问题，我必须在函数中的任何地方不断地使用“fromIntegral”。例如：

import Data.List

roundDouble
    :: Double
    -> Int 
    -> Double
roundDouble x acc = fromIntegral (round $ x * 10 ** fromIntegral acc) / 10 ** fromIntegral acc

有没有更简单的写法？ （我知道可能有更简单的方法来对数字进行四舍五入，如果有请告诉我！但是我主要感兴趣的是如何避免使用这么多“fromIntegrals”。）

谢谢，Ash

Answer 1

有时我发现辅助函数很有用：

roundDouble x acc = (round $ x * 10 ^ acc) /. (10 ^ acc)
    where 
    x /. y = fromIntegral x / fromIntegral y

该辅助函数也可以编写为：

(/.) = (/) `on` fromIntegral

Where on is from Data.Function。

Answer 2

您可以使用 ^ 代替 **。 ^ 将任何 Integral 作为第二个参数，因此您无需对第二个操作数调用 fromIntegral。所以你的代码变成：

roundDouble x acc = fromIntegral (round $ x * 10 ^ acc) / 10 ^ acc

其中只有一个 fromIntegral。而您无法摆脱的那个，因为 round 自然会返回一个 Integral，并且您无法对 Integral 执行非整数除法。

Answer 3

我对封送代码也有类似的问题，其中 fromIntegral 用于将 CInt 转换为 Int。我通常定义 fI = fromIntegral 以使其更容易。您可能还需要为其提供显式类型签名或使用 -XNoMonomorphismRestriction。

如果您需要进行大量数学运算，则可能需要查看 数值Prelude，它似乎在不同数字类型之间有更合理的关系。

Answer 4

另一个想法，类似于luqui的。我与 fromIntegral 相关的大多数问题都与将 Int 除以 Double 或 Double 除以 Int 的必要性有关。因此，这个 (/.) 允许划分任意两个 Real 类型，不一定相同，也不一定是 Integral 类型，如 luqui 的解决方案中所示：

(/.) :: (Real a, Real b, Fractional c) => a -> b -> c
(/.) x y = fromRational $ (toRational x) / (toRational y)

示例：

ghci> let (a,b,c) = (2::Int, 3::Double, 5::Int)
ghci> (b/.a, c/.a, a/.c)
(1.5,2.5,0.4)

它适用于任何两个Real，但我怀疑有理数除法和与Rational之间的转换不是很有效。

现在你的例子变成：

roundDouble :: Double -> Int -> Double
roundDouble x acc = (round $ x * 10 ^ acc) /. (10 ^ acc)