下一个、上一个并行文件夹

Question

我正在尝试使用批处理文件和程序创建一个相对快捷方式，以使用图标在 exe 程序中转换批处理。

我需要一个“快捷方式”来在资源管理器窗口中打开下一个字母并行文件夹，并需要一个“快捷方式”来打开上一个。理想情况下，我什至希望它关闭用于双击它的资源管理器窗口。

到目前为止，我已经：

@echo off
echo %cd%
for %%a in ("%cd%") do set folder=%%~na
pushd ..
echo %folder%
echo .
dir /A:D /B
pause

％folder％具有执行批处理的文件夹的名称（不是路径！）。

该行： dir /A:D /B 为您提供多行输出，为您提供所有并行文件夹（因为我使用 Pushd 提升了一个级别..）。我真的需要找到一种方法来搜索 %fodler% 值并选择它上方或下方的行。

我尝试使用 for /f 进行一些操作，但在处理多行而不是单个字符串时，它并没有那么有用。

有什么想法吗？

Answer 1

尽管我不太清楚您到底想要实现什么，但以下代码片段应该可以满足您的要求。只需将其添加到您的脚本中即可：

setlocal enabledelayedexpansion

for /f %%a in ('dir /b /ad /on') do (

   @rem shift the current value through the variables
   set previous=!current!
   set current=!next!
   set next=%%a

   @rem check if the "current" value is the right one
   if "!current!"=="%folder%" goto :found
)

@rem if we get here the loop has finished without %current% having the expected value
@rem but we need to check if it was the last folder in the directory
if "%next%"=="%folder%" (
    set previous=%current%
    set current=%next%
    set next=
    goto :found
)

endlocal

@rem exit here if no match is found (should never happen)
goto :eof

@rem variables should have valid values
:found
echo %previous%
echo %current%
echo %next%

说明：

3 个变量 previous、current 和 next 的使用方式类似于轮班登记。在每次循环迭代中，当前目录值通过变量移动一位

在移动结束时，将测试当前变量是否为所需的文件夹

如果循环在条件为真之前结束，这意味着最后一个文件夹是正确的，因此尾随移动。

希望有帮助...