如何在 T-SQL 存储过程中使用可选参数？

Question

我正在创建一个存储过程来搜索表。我有许多不同的搜索字段，所有这些都是可选的。有没有办法创建一个存储过程来处理这个问题？假设我有一个包含四个字段的表：ID、FirstName、LastName 和 Title。我可以做这样的事情：

CREATE PROCEDURE spDoSearch
    @FirstName varchar(25) = null,
    @LastName varchar(25) = null,
    @Title varchar(25) = null
AS
    BEGIN
        SELECT ID, FirstName, LastName, Title
        FROM tblUsers
        WHERE
            FirstName = ISNULL(@FirstName, FirstName) AND
            LastName = ISNULL(@LastName, LastName) AND
            Title = ISNULL(@Title, Title)
    END

这种工作。但是，它会忽略 FirstName、LastName 或 Title 为 NULL 的记录。如果搜索参数中未指定标题，我想包含标题为 NULL 的记录 - 名字和姓氏相同。我知道我可以使用动态 SQL 来做到这一点，但我想避免这种情况。

Answer 1

根据给定参数动态改变搜索是一个复杂的主题，并且以一种不同的方式进行，即使只有非常微小的差异，也会产生巨大的性能影响。关键是使用索引，忽略紧凑的代码，忽略重复代码的担忧，必须制定好的查询执行计划（使用索引）。

阅读本文并考虑所有方法。您的最佳方法将取决于您的参数、数据、架构和实际使用情况：

动态搜索条件在 T-SQL 中，作者：Erland Sommarskog

动态 SQL 的诅咒与祝福，作者：Erland Sommarskog

如果您有正确的 SQL Server 2008 版本（SQL 2008 SP1 CU5 (10.0.2746) 及更高版本），您可以使用这个小技巧来实际使用索引：

将 OPTION (RECOMPILE) 添加到您的查询，参见 Erland 的文章，SQL Server 将解析 在基于局部变量的运行时值创建查询计划之前，从 (@LastName IS NULL OR LastName= @LastName) 中执行 OR，并且可以使用索引。

这适用于任何 SQL Server 版本（返回正确的结果），但仅当您使用 SQL 2008 SP1 CU5 (10.0.2746) 及更高版本时才包含选项(RECOMPILE)。 OPTION(RECOMPILE) 将重新编译您的查询，只有列出的版本才会根据局部变量的当前运行时值重新编译它，这将为您提供最佳性能。如果不在该版本的 SQL Server 2008 上，则将该行保留为关闭。

CREATE PROCEDURE spDoSearch
    @FirstName varchar(25) = null,
    @LastName varchar(25) = null,
    @Title varchar(25) = null
AS
    BEGIN
        SELECT ID, FirstName, LastName, Title
        FROM tblUsers
        WHERE
                (@FirstName IS NULL OR (FirstName = @FirstName))
            AND (@LastName  IS NULL OR (LastName  = @LastName ))
            AND (@Title     IS NULL OR (Title     = @Title    ))
        OPTION (RECOMPILE) ---<<<<use if on for SQL 2008 SP1 CU5 (10.0.2746) and later
    END

Answer 2

@KM 的答案就目前而言是好的，但未能完全遵循他早期的建议之一；

...，忽略紧凑的代码，忽略对重复代码的担忧，...

如果您希望获得最佳性能，那么您应该为可选条件的每个可能组合编写一个定制查询。这听起来可能很极端，如果您有很多可选标准，那么它可能会很极端，但性能通常是努力和结果之间的权衡。在实践中，可能存在一组通用的参数组合，可以针对定制查询，然后针对所有其他组合进行通用查询（根据其他答案）。

CREATE PROCEDURE spDoSearch
    @FirstName varchar(25) = null,
    @LastName varchar(25) = null,
    @Title varchar(25) = null
AS
BEGIN

    IF (@FirstName IS NOT NULL AND @LastName IS NULL AND @Title IS NULL)
        -- Search by first name only
        SELECT ID, FirstName, LastName, Title
        FROM tblUsers
        WHERE
            FirstName = @FirstName

    ELSE IF (@FirstName IS NULL AND @LastName IS NOT NULL AND @Title IS NULL)
        -- Search by last name only
        SELECT ID, FirstName, LastName, Title
        FROM tblUsers
        WHERE
            LastName = @LastName

    ELSE IF (@FirstName IS NULL AND @LastName IS NULL AND @Title IS NOT NULL)
        -- Search by title only
        SELECT ID, FirstName, LastName, Title
        FROM tblUsers
        WHERE
            Title = @Title

    ELSE IF (@FirstName IS NOT NULL AND @LastName IS NOT NULL AND @Title IS NULL)
        -- Search by first and last name
        SELECT ID, FirstName, LastName, Title
        FROM tblUsers
        WHERE
            FirstName = @FirstName
            AND LastName = @LastName

    ELSE
        -- Search by any other combination
        SELECT ID, FirstName, LastName, Title
        FROM tblUsers
        WHERE
                (@FirstName IS NULL OR (FirstName = @FirstName))
            AND (@LastName  IS NULL OR (LastName  = @LastName ))
            AND (@Title     IS NULL OR (Title     = @Title    ))

END

这种方法的优点是，在定制查询处理的常见情况下，查询尽可能高效 - 不受未提供的条件的影响。此外，索引和其他性能增强可以针对特定的定制查询，而不是试图满足所有可能的情况。

Answer 3

您可以在以下情况下执行此操作，

CREATE PROCEDURE spDoSearch
   @FirstName varchar(25) = null,
   @LastName varchar(25) = null,
   @Title varchar(25) = null
AS
  BEGIN
      SELECT ID, FirstName, LastName, Title
      FROM tblUsers
      WHERE
        (@FirstName IS NULL OR FirstName = @FirstName) AND
        (@LastNameName IS NULL OR LastName = @LastName) AND
        (@Title IS NULL OR Title = @Title)
END

但是有时取决于数据，更好地创建动态查询并执行它们。

Answer 4

聚会迟到了五年。

它在所接受的答案的提供的链接中提到，但我认为它值得在 SO 上有一个明确的答案 - 根据提供的参数动态构建查询。例如：

设置

-- drop table Person
create table Person
(
    PersonId INT NOT NULL IDENTITY(1, 1) CONSTRAINT PK_Person PRIMARY KEY,
    FirstName NVARCHAR(64) NOT NULL,
    LastName NVARCHAR(64) NOT NULL,
    Title NVARCHAR(64) NULL
)
GO

INSERT INTO Person (FirstName, LastName, Title)
VALUES ('Dick', 'Ormsby', 'Mr'), ('Serena', 'Kroeger', 'Ms'), 
    ('Marina', 'Losoya', 'Mrs'), ('Shakita', 'Grate', 'Ms'), 
    ('Bethann', 'Zellner', 'Ms'), ('Dexter', 'Shaw', 'Mr'),
    ('Zona', 'Halligan', 'Ms'), ('Fiona', 'Cassity', 'Ms'),
    ('Sherron', 'Janowski', 'Ms'), ('Melinda', 'Cormier', 'Ms')
GO

过程

ALTER PROCEDURE spDoSearch
    @FirstName varchar(64) = null,
    @LastName varchar(64) = null,
    @Title varchar(64) = null,
    @TopCount INT = 100
AS
BEGIN
    DECLARE @SQL NVARCHAR(4000) = '
        SELECT TOP ' + CAST(@TopCount AS VARCHAR) + ' *
        FROM Person
        WHERE 1 = 1'

    PRINT @SQL

    IF (@FirstName IS NOT NULL) SET @SQL = @SQL + ' AND FirstName = @FirstName'
    IF (@LastName IS NOT NULL) SET @SQL = @SQL + ' AND FirstName = @LastName'
    IF (@Title IS NOT NULL) SET @SQL = @SQL + ' AND Title = @Title'

    EXEC sp_executesql @SQL, N'@TopCount INT, @FirstName varchar(25), @LastName varchar(25), @Title varchar(64)', 
         @TopCount, @FirstName, @LastName, @Title
END
GO

使用

exec spDoSearch @TopCount = 3
exec spDoSearch @FirstName = 'Dick'

优点：

• 易于编写和理解
• 灵活性 - 轻松生成更复杂的过滤查询（例如动态 TOP）

缺点：

• 可能性能问题取决于提供的参数、索引和数据量

不是直接答案，但与问题（又名大局）相关

通常，这些过滤存储过程不会浮动，而是从某个服务层调用。这就留下了将业务逻辑（过滤）从 SQL 移至服务层的选项。

一个示例是使用 LINQ2SQL 根据提供的过滤器生成查询：

    public IList<SomeServiceModel> GetServiceModels(CustomFilter filters)
    {
        var query = DataAccess.SomeRepository.AllNoTracking;

        // partial and insensitive search 
        if (!string.IsNullOrWhiteSpace(filters.SomeName))
            query = query.Where(item => item.SomeName.IndexOf(filters.SomeName, StringComparison.OrdinalIgnoreCase) != -1);
        // filter by multiple selection
        if ((filters.CreatedByList?.Count ?? 0) > 0)
            query = query.Where(item => filters.CreatedByList.Contains(item.CreatedById));
        if (filters.EnabledOnly)
            query = query.Where(item => item.IsEnabled);

        var modelList = query.ToList();
        var serviceModelList = MappingService.MapEx<SomeDataModel, SomeServiceModel>(modelList);
        return serviceModelList;
    }

优点：

• 根据提供的过滤器动态生成查询。否 参数嗅探或重新编译< /a> 需要的提示
• 对于那些在 OOP 世界中通常性能友好的人来说更容易编写
• ，因为将发出“简单”查询（尽管仍然需要适当的索引）

缺点：

• 可能会达到 LINQ2QL 限制并强制降级到 LINQ2Objects 或继续回到纯 SQL 解决方案，具体取决于具体情况，
• 不小心编写 LINQ 可能会生成糟糕的查询（或许多查询，如果加载了导航属性）

Answer 5

扩展您的 WHERE 条件：

WHERE
    (FirstName = ISNULL(@FirstName, FirstName)
    OR COALESCE(@FirstName, FirstName, '') = '')
AND (LastName = ISNULL(@LastName, LastName)
    OR COALESCE(@LastName, LastName, '') = '')
AND (Title = ISNULL(@Title, Title)
    OR COALESCE(@Title, Title, '') = '')

即将不同的情况与布尔条件结合起来。

Answer 6

这也有效：

    ...
    WHERE
        (FirstName IS NULL OR FirstName = ISNULL(@FirstName, FirstName)) AND
        (LastName IS NULL OR LastName = ISNULL(@LastName, LastName)) AND
        (Title IS NULL OR Title = ISNULL(@Title, Title))