如何打开已 cd 到的特定路径的终端？

Question

如何使用终端打开另一个终端窗口，但使用我指定的路径？

当我开始工作时，我正在使用自动化程序加载我的工作内容，但我需要知道如何执行此操作：

打开终端并输入：
• cd 工作/公司/项目/
• script/server

然后在该终端窗口中创建新选项卡并 cd 到同一文件夹。

Answer 1

这会从 Mac OSX 上的命令提示符打开一个新的终端窗口，执行“cd /”，然后将窗口保持在顶部：

osascript -e 'tell application "terminal"' -e 'do script "cd /"' -e 'end tell'

您可以将其放入这样的脚本中：

#!/bin/sh
osascript -e 'tell application "terminal"' -e "do script \"cd $1\"" -e 'end tell'

希望这会有所帮助。

Answer 2

使用 applescript 来执行此操作。

例如 在此处打开终端

Answer 3

您可以编写一个 shell 脚本来 cd 到该目录

因此编写一个执行 cd /user/music 或类似内容的脚本，将其另存为 myscript.sh 并使用 chmod +x myscript.sh 运行它。

这个 资源非常有帮助

Answer 4

下面的两个脚本一起处理常见场景：

1) 如果终端已在运行，请打开一个新的终端窗口并在其中运行“cd mydir”

2) 如果终端尚未运行，请使用终端生成的初始窗口（窗口 0 ），而不是烦人地启动第二个窗口

注意：不太完美的是，如果终端打开了多个窗口，所有这些窗口都会被带到前面，与任何其他应用程序重叠。仅将最后一个终端窗口提升到前面的解决方案似乎需要 AppleScriptObjC 的黑魔法 - 参考如下：

https://apple.stackexchange.com/questions/39204/script-to-raise-a-single-window-to-the-front
http://tom.scogland.com /blog/2013/06/08/mac-raise-window-by-title/

脚本 1 - 打开文本编辑器并另存为：

/usr/local/bin/terminal-here.sh

#!/bin/sh
osascript `dirname $0`/terminal-here.scpt $1 > /dev/null 2> /dev/null

脚本 2 - 打开“AppleScript 编辑器”，粘贴下面的内容并另存为：

/usr/local/bin/terminal-here.scpt

# AppleScript to cd (change directory) to a path passed as an argument

# If Terminal.app is running, the script will open a new window and cd to the path
# If Terminal.app is NOT running, we'll use the window that Terminal opens automatically on launch

# Run script with passed arguments (if any)
on run argv
    if (count of argv) > 0 then
        # There was an argument passed so consider it to be the path
        set mypath to item 1 of argv
    else
        # Since no argument was passed, default to the home directory
        set mypath to "~"
    end if
    tell application "System Events"
        if (count (processes whose bundle identifier is "com.apple.Terminal")) is 0 then
            # Terminal isn't running so we'll make sure to run the 'cd' in Terminal's first window (0)
            tell application "/Applications/Utilities/Terminal.app"
                # Turn off echo, run the 'cd', clear screen, empty the scrollback, re-enable echo
                do script "stty -echo; cd " & (mypath as text) & ";clear; printf \"\\e[3J\"; stty echo" in window 0
                activate last window
            end tell
        else
            # Terminal is already running so we'll let it open a new window for our 'cd' command
            tell application "/Applications/Utilities/Terminal.app"
                # Turn off echo, run the 'cd', clear screen, empty the scrollback, re-enable echo
                do script "stty -echo; cd " & (mypath as text) & ";clear; printf \"\\e[3J\"; stty echo"
                activate last window
            end tell
        end if
    end tell
end run