C# 合并 xml 中的命名空间引用

Question

我有由atom 格式化程序格式化的xml。 原子格式化程序似乎多次指定内联命名空间。

有什么办法可以轻松整合这些。 下面的示例显示了为每个属性指定了三次的命名空间。 这太可怕了。

我希望文档顶部有前缀，并且文档中没有命名空间（只是前缀）。是否有编写器或格式化程序选项可以实现此目的？

<property p3:name="firstname" xmlns:p3="http://a9.com/-/opensearch/extensions/property/1.0/" xmlns="http://a9.com/-/opensearch/extensions/property/1.0/">Drikie</property>

谢谢克雷格

。

Answer 1

原子格式化程序似乎指定
命名空间内联多次。

有什么办法可以轻松整合
这些。下面的例子显示
指定了三次的命名空间
每个属性。这太可怕了。

生成这种更紧凑格式的最简单方法是在 XML 文档上应用以下 XSLT 转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()[not(self::*)]|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="*">
  <xsl:element name="{name()}" namespace="{namespace-uri()}">
   <xsl:copy-of select="descendant::*/namespace::*"/>
   <xsl:copy-of select="namespace::*"/>

   <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

例如，当应用于以下 XML 文档时（根据您的问题):

<t xmlns="http://a9.com/-/opensearch/extensions/property/1.0/">
<property p3:name="firstname"
  xmlns:p3="http://a9.com/-/opensearch/extensions/property/1.0/"
  xmlns="http://a9.com/-/opensearch/extensions/property/1.0/"
  >Drikie</property>
</t>

产生了想要的结果:

<t
 xmlns="http://a9.com/-/opensearch/extensions/property/1.0/"
 xmlns:p3="http://a9.com/-/opensearch/extensions/property/1.0/">
    <property p3:name="firstname">Drikie</property>
</t>

请注意:

1. 命名空间声明不能进一步提升到具有绑定相同前缀的声明的元素之上到另一个命名空间。

2. 将命名空间声明提升到祖先元素可能会增加解析的 XML 文档的大小，因为所有命名空间节点都会向下传播到所有后代节点，其中一些节点可能根本不需要该命名空间.