如何捕获所有需要用户交互的 elisp 函数调用？

Question

我想编写一个函数来调用 emacs 中的函数列表（具体来说，kill-buffer-query-functions），但如果其中任何一个需要用户交互，我想让它们简单地返回相反，nil，这样整个过程将以非交互方式运行。我正在考虑使用 defadvice 来修改通常会提示用户抛出值为 nil 的异常的每个函数。然后我将用 catch 表单包装所有内容。唯一的麻烦是，我没有可能提示用户输入某些内容的所有 emacs elisp 函数的详尽列表。

有谁有这样的列表，或者有更简单的方法吗？例如，函数 yes-or-no-p 和 y-or-np 肯定会出现在这个列表中，read-string 也会出现在这个列表中> 和完成读取。

基本上，我想填写此代码中的省略号：

(defun eval-but-return-if-requires-user (form &optional interactive-return)
  "Evaluate FORM, but immediately stop and return INTERACTIVE-RETURN if any part of FORM would require user interaction."
  ;; Set up the safety net
  (catch 'ui-required 
    (let ((ui-requiring-functions '(  ...  )) ; What goes in this list?
          (ui-required-callback 
           ;; A function that takes any number of args and throws an exception
           '(lambda (&rest args) 
              (throw 'ui-required interactive-return)))
          (flet-redefinitions
           ;; Use the above callback to create a list of redefinitions for `flet'
           (mapcar (lambda (func) 
                     (cons func (cdr ui-required-callback))) 
                   ui-requiring-functions)))
      `(flet 
           ,flet-redefinitions          ; Perform the function redefinitions,
         ,form))))                      ; Then evaluate FORM

基本上，我将所有内容包装在 catch 块中，然后定义一个函数体，该函数体将简单地接受任何参数并抛出适当的异常。我设置了一个要传递给 flet 的重定义列表，它将临时重新定义这些函数以使用前面提到的异常抛出主体。最后，我使用这些临时函数重新定义来评估 form 。

现在，该代码中可能存在一些引用错误，但我认为如果我有要重新定义的函数的适当列表，它就会起作用。

请注意，如果需要任何用户交互，我希望返回整个表单，而不仅仅是表单中需要用户交互的特定函数调用。要了解为什么我需要这个，请考虑该表单可能想要询问以下任一问题：

• 您想删除这个非常重要的文件吗？是或否
• 您想保留这个非常重要的文件吗？是或否

显然，如果我只是修改了 yes-or-no-p 来始终返回 nil （这意味着“否”），仍然不能保证保存我的重要文件免遭删除。因此，由于我不知道可能会问什么问题，所以如果它想询问用户任何问题，我想让整个表单简单地中止并返回特定值。

本质上，我想说“评估这段代码，但如果你必须问我任何问题才能这样做，那就忘记它并返回 nil 。”

Answer 1

我认为你可以使用“commandp”来判断特定功能是否是交互式的。

所以只需运行 (remove-if 'commandp Kill-buffer-query-functions)

Answer 2

我刚刚偶然发现了一个可能的答案：

Mx describe-function minibuffer-with-setup-hook

（带设置挂钩的迷你缓冲区乐趣和休息
身体）

将 FUN 添加到“minibuffer-setup-hook”
执行 BODY 时。身体应该使用
迷你缓冲区最多一次。递归
迷你缓冲区的使用不会
受影响。

因此，使用它，如果我想评估 BODY 但如果 BODY 尝试使用迷你缓冲区，则中止并返回 nil，也许我可以使用这个:

(catch 'tried-to-use-minibuffer
  (minibuffer-with-setup-hook 
      (lambda (&rest args) (throw 'tried-to-use-minibuffer nil))
    BODY))

稍后我会测试一下。

---

后来的事了，我已经测试过了。效果很好。这是我的最终代码：

(defmacro without-minibuffer (&rest body)
  "Like `progn', but stop and return nil if any of BODY forms tries to use the minibuffer.

Also disable dialogs while evaluating BODY forms, since dialogs
are just an alternative to the minibuffer."
  `(catch 'tried-to-use-minibuffer
     (minibuffer-with-setup-hook
         (lambda (&rest args) (throw 'tried-to-use-minibuffer nil))
       (let ((use-dialog-box))          ; No cheating by using dialogs instead of minibuffer
         ,@body))))

;; This should be indented like progn
(put 'without-minibuffer 'lisp-indent-function (get 'progn 'lisp-indent-function))