如何移动文件夹中的每四个项目？

Question

我正在尝试制作一个脚本，将文件夹中的每四个项目移动到目标文件夹。到目前为止，我已经：

tell application "Finder"
    set originFolder to folder choose folder
    set dest1Folder to folder choose folder
    set dest2Folder to folder choose folder
    set quarter to 1
    repeat with i from 1 to count of items in originFolder
        if quarter is 1 then
            move item i of originFolder to dest1Folder
        else
            move item i of originFolder to dest2Folder

        end if
        if quarter is 4 then
            set quarter to 0
        end if
        set quarter to quarter + 1
    end repeat
end tell

但这给了我

error "Finder got an error: Expected a reference." number -1727

为什么这不起作用以及什么会起作用？

Answer 1

您的脚本中存在一些问题：

在设置 choosefolder 变量时，您必须在 choosefolder 两边加上括号，以强制 Finder 将 别名由选择文件夹返回到对象说明符：

set originFolder to folder (choose folder)

移动项目的循环将终止并出现索引越界错误，因为随着项目的移动，originFolder 中的项目在循环的每次迭代中都会发生变化。

更好的解决方案是首先计算应移动的文件的索引，然后让 Finder 一步执行移动操作：

tell application "Finder"
    set originFolder to folder (choose folder)
    set destFolder to folder (choose folder)
    set indexes to {}
    repeat with i from 4 to (count of items in originFolder) by 4
        copy i to end of indexes
    end repeat
    move (every item of originFolder whose index is in indexes) to destFolder
end tell