通过多项选择找出 Spark 列表中取消选择的项目

Question

在 Spark 列表中，我可以使用 change 事件来找出已选择或取消选择的项目。 分派的 IndexChangeEvent 对象具有保存此信息的属性 newIndex 和 oldIndex。

但在允许多重选择的情况下，这不再起作用，因为 newIndex 和 oldIndex 可以引用仍然选定的元素的索引。

解决方案是将 selectedIndices 向量复制到另一个变量，并在选择更改后将此变量与 selectedIndices 进行比较，但这似乎有些复杂。

有谁知道是否有一种简单的方法可以获取用户取消选择而其他元素仍处于选中状态的索引/项目？

Answer 1

您将需要存储选定的索引并比较差异。

private static function findMissing(ar1:Array, ar2:Array):Array
{
    var missing:Array = [];
    for each(var item:Object in ar1)
    {
        if(ar2.indexOf(item) < 0)
            missing.push(item);
    }

    return missing;
}

Answer 2

扩展自定义数据对象

• 您还可以使用可绑定的布尔属性 ：
  _selected，通过列表交互进行更新。
• 和一个可以触发的事件
  它：selectionChanged。

在 selected 设置器中 - 如果它确实发生了变化 - 您可以触发自己的冒泡 selectionChanged 事件，并在需要的地方捕获它。

SelectableItem.as - 表示列表的行数据的自定义数据结构

[Bindable]
[Event(name="selectionChanged",type="flash.events.Event")]
public class SelectableItem
{
    public static const EVENT_SELECTION_CHANGED:String = 'selectionChanged';
    private var _selected:Boolean;
    private var _name:String;

    public function SelectableItem()
    {
    }

    public function get selected():Boolean
    {
        return _selected;
    }

    public function set selected(value:Boolean):void
    {
        if (_selected != value)
        {
            _selected = value;
            dispatchEvent(new Event(EVENT_SELECTION_CHANGED, true));
        }
    }

    public function get name():String
    {
        return _name;
    }

    public function set name(value:String):void
    {
        _name = value;
    }
}

MyDataGrid.mxml

<?xml version="1.0" encoding="utf-8"?>
<mx:DataGrid xmlns:fx="http://ns.adobe.com/mxml/2009" 
    xmlns:s="library://ns.adobe.com/flex/spark" 
    xmlns:mx="library://ns.adobe.com/flex/mx" 
    allowMultipleSelection="true">
    <fx:Script>
        <![CDATA[
            import mx.controls.listClasses.IListItemRenderer;

            protected override function updateRendererDisplayList(r:IListItemRenderer):void
            {
                super.updateRendererDisplayList(r);
                if (r && r.data)
                    r.data.selected = DataGrid(r.owner).isItemSelected(r.data);
            }

        ]]>
    </fx:Script>
</mx:DataGrid>

TestApplication.mxml

<fx:Script>
    <![CDATA[
        import mx.collections.ArrayCollection;
        import mx.events.FlexEvent;

        [Bindable]
        private var list:ArrayCollection = new ArrayCollection();

        protected function onCreationComplete(event:FlexEvent):void
        {
            for (var i:int = 0; i < 20; i++)
            {
                var item:SelectableItem= new SelectableItem();
                item.name = 'Item ' + i;
                item.addEventListener(SelectableItem.EVENT_SELECTION_CHANGED, onItemSelectionChanged);
                list.addItem(item);
            }
        }

        private function onItemSelectionChanged(event:Event):void
        {
            trace(event);
        }

    ]]>
</fx:Script>
<my:MyDataGrid dataProvider="{list}" width="100%" height="100%" />

我希望这会有所帮助。