XSL 中每组值的最大总和

Question

对于这个问题可能有一个非常简单的解决方案。我可以在 C#-LINQ 中轻松完成此操作。不幸的是，我对 XPath 和 XSL 不太有经验。

我有一个包含以下结构的输入 XML 文件：

<group>
    <val>1</val>
    <val>3</val>
    <val>1</val>
</group>
<group>
    <val>3</val>
    <val>2</val>
    <val>2</val>
</group>

现在，在我的 XSL 转换中，我想定义 1 个变量“highestsum”，其中包含“值”的最高总和。因此，对于该示例，它将返回 7，即第二组中所有值的总和。

经过一番搜索，这是我找到的最接近的解决方案：

http://w3schools.invisionzone。 com/index.php?showtopic=24265

但我有一种感觉，有比在模板中使用排序更好的方法来实现此结果。有接受者吗？

Answer 1

我。一个好的 XSLT 1.0 解决方案（简洁、高效且易于理解）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/*">
   <xsl:for-each select="group">
     <xsl:sort select="sum(val)" data-type="number"
      order="descending"/>

     <xsl:if test="position()=1">
       <xsl:value-of select="sum(val)"/>
     </xsl:if>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<t>
    <group>
        <val>1</val>
        <val>3</val>
        <val>1</val>
    </group>
    <group>
        <val>3</val>
        <val>2</val>
        <val>2</val>
    </group>
</t>

生成所需的正确结果：

7

要获取所需的变量定义，只需将上述代码中的 指令放入变量主体即可。

二.一种更好的 XSLT 2.0（实际上是 XPath 2.0 单行）解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/*">
   <xsl:sequence select="max(group/sum(val))"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于同一个 XML 文档时，会产生相同的正确答案：

7

并且想要的变量定义很简单：

  <xsl:variable name="vHighestSum" 
       select="max(group/sum(val))"/>

最后，可以在 XQuery 中使用相同的 Xpath 表达式来定义所需的变量：

let $vHighestSum := max(/*/group/sum(val))