状态单子哈斯克尔

Question

我想编写一个函数来使用 haskell 中的 State Monad 计算平均值 这是我编写的代码，

import Control.Monad.State
type MyState = (Double,Double)
media s (a,n)= ((a*n+s)/(n+1),n+1)

getAverage:: Double ->State MyState  s1-> Double
getAverage s c=get >>= \s0 -> let (x,s1) =media s s0
            in put s1 >> return x

在 GHCI 中编译时出现此错误，我卡在那里 你能帮助我了解问题所在吗，提前谢谢你

Answer 1

您提供的代码给出了此错误：

Couldn't match expected type `Double'
       against inferred type `m Double'
In the expression:
      get >>= \ s0 -> let (x, s1) = ... in put s1 >> return x
In the definition of `getAverage':
    getAverage s c = get >>= \ s0 -> let ... in put s1 >> return x

所有这意味着表达式（“推断”）产生的类型与类型签名（“预期”）不一致。在本例中，getAverage 在 State monad 中运行，因此类型签名不正确，因为它无法计算为非 Monadic 类型。

然而，除此之外，您的代码还有其他问题，即使在修复该特定问题后也无法编译。首先是一些风格问题，以使其更具可读性：

• getAverage 有一个未使用的参数，据说它是 State monad 中的一个值，无论如何它实际上没有意义。
• 使用 do 表示法通常比使用 (>>=) 和 lambda 更清晰，尤其是对于 State 之类的东西。
• 第二行的缩进令人困惑，因为 in 与 lambda 内部 的 let 相匹配。

进行这些更改后，我们得到了：

getAverage s = do
    s0 <- get
    let (x, s1) = media s s0
    put s1 
    return x

...这使得更容易发现下一个错误：media 的第二个参数是一个 2 元组，而 s1 只是一个单个数字，但您尝试将两者用作状态值。也许您想要的是将状态设置为 (x, s1)，但仅返回 x。

getAverage s = do
    s0 <- get
    let (x,s1) = media s s0
    put (x,s1)
    return x

编译得很好，但仍然需要一些整理：

• media 需要更新整个状态值，所以不是 getting 和 putting，只需使用修改功能即可。
• 返回值是状态值的第一部分，因此只需通过 get 进行 fmap ing fst 就更简单了。

所以现在我们有了这样的东西：

media :: Double -> MyState -> MyState
media s (a, n) = ((a * n + s) / (n + 1), n + 1)

getAverage:: Double -> State MyState Double
getAverage s = do
    modify (media s)
    fmap fst get

我们还可以注意到 getAverage 是在做两件不同的事情，并将其分成单独的函数：

updateAverage:: Double -> State MyState ()
updateAverage s = modify (media s)

currentAverage :: State MyState Double
currentAverage = fmap fst get

getAverage:: Double -> State MyState Double
getAverage s = updateAverage s >> currentAverage

编辑：因为我忘记了实际上从 monad 中获取结果的小细节，在 Travis Brown 的 getAverages 函数中用 getAverage 替换 updateAverage 将让它在我的上面的代码。

Answer 2

注意：camccann 的答案比我的好，但我的方法略有不同，并给出了如何评估状态单子的示例，所以我将其留在这里供参考。

---

我们可以通过删除 getAverage 的类型签名和函数中未出现的参数 (c) 来开始尝试找出问题：

getAverage s=get >>= \s0 -> let (x,s1) =media s s0
            in put s1 >> return x

这仍然没有编译，因为我们试图放入一些没有正确类型的东西：s1是一个Double，而不是一个我的状态。这很容易解决：

getAverage s=get >>= \s0 -> let s1@(x,_) =media s s0
            in put s1 >> return x

我们也可以保持 let 模式不变，只说 put (x,s1)：我这样做是为了让我们的 >s1 与 s0 具有相同的类型。

这可以编译，所以现在我们可以修复类型签名。如果我们向 GHCi 询问类型，它会返回以下内容：

getAverage :: (Fractional t, MonadState (t, t) m) => t -> m t

Double 是 Fractional 的实例，State MyState 是 State MyState 的实例>MonadState (Double, Double)，因此我们可以使用与您的原始类型非常相似的东西来进行 getAverage：

getAverage :: Double -> State MyState Double

此函数并不真正“获取”平均值：它会在添加后更新平均值一个新值，所以让我们适当地重命名它：

updateAverage :: Double -> State MyState Double
updateAverage s=get >>= \s0 -> let s1@(x,_) =media s s0
            in put s1 >> return x

现在我们可以定义一个 getAverages 函数，它接受一个 Double 列表，通过 updateAverage 运行它们，并返回每一步的中间平均值列表：

getAverages :: [Double] -> [Double]
getAverages ss = evalState (mapM updateAverage ss) (0, 0)

这符合我们的预期：

*Main> getAverages [1..10]
[1.0,1.5,2.0,2.5,3.0,3.5,4.0,4.5,5.0,5.5]

请注意，要使用 State monad 执行任何有用的操作，您始终必须使用 evalState< /code> （或密切相关的 runState 和 execState）。