在安全模式下打开 Word（从 Outlook VBA）

Question

我有一个 Word 文档作为电子邮件的附件，我需要从中获取一些数据以传递到 URL。为此，我将附件保存到本地临时文件，然后打开文档，然后使用 Word 对象模型从文档中的表中提取数据。

在 VBA 中打开文档时，我遇到了一些问题：首先，它非常慢，因为我们有一些公司宏内容在 Word 打开时加载；其次，如果在 Word 打开时出现任何消​​息（例如文档恢复内容），代码就会挂起并且 Word 永远不会关闭。

所以，我的问题是我可以从 VBA 以安全模式打开 Word，这样除了基本文档之外什么都可用（因为这就是我所需要的）？或者，是否有更好的方法来控制 Word 来解决我遇到的问题？

Answer 1

也许使用 shell 以安全模式打开，说：

"C:\Program Files\Microsoft Office\Office11\Winword.exe" /a

然后使用 GetObject 获取实例。

更多详细信息：

Dim wd As Object
Dim strWord As String, strDoc As String
Dim intSection As Integer
Dim intTries As Integer

    On Error GoTo ErrorHandler

    strWord = "C:\Program Files\Microsoft Office\Office11\WinWord.Exe"
    strDoc = "C:\Docs\ADoc.doc"

    Shell """" & strWord & """ /a", vbMinimizedFocus

    ''Set focus to something other than the word document
    ''See http://support.microsoft.com/kb/238610
    Forms!MyForm.SetFocus

    intSection = 1 ''attempting GetObject...
    Set wd = GetObject(, "Word.Application")
    intSection = 0 ''resume normal error handling

    wd.Documents.Open strDoc

    ''Code here

    Set wd = Nothing

    ''Exit procedure:
    Exit Sub

ErrorHandler:
    If intSection = 1 Then
        intTries = intTries + 1
        If intTries < 20 Then
            Sleep 500 '' wait 1/2 seconds
            Resume ''resume code at the GetObject line
        Else
            MsgBox "GetObject still failing. Process ended.", _
                vbMsgBoxSetForeground
        End If
    Else ''intSection = 0 so use normal error handling:
        MsgBox Error$
    End If

对于睡眠，需要位于模块顶部：

Private Declare Sub Sleep Lib "kernel32" _
    (ByVal dwMilliseconds As Long)

---

/a 启动 Word 并防止自动加载加载项和全局模板（包括 Normal 模板）。

/a 开关还锁定设置文件；也就是说，如果使用此开关，则无法读取或修改设置文件。