将 XSLT 输入文档前缀映射到首选值

Question

使用 XSLT，我想知道如何让输出使用样式表的名称空间前缀而不是输入文档的前缀。举例来说，给出这个非常简化的文档：

<?xml version="1.0"?>
<a:node xmlns:a="urn:schemas:blah:"/>

以及以下 XSL 转换：

<?xml version="1.0"?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:blah="urn:schemas:blah:" version="2.0">
   <xsl:output indent="yes">
   <xsl:template match="/blah:node">
      <xsl:copy/><!-- marked -->
   </xsl:template>
</xsl:transform>

我可以告诉处理器（Saxon8，如果重要的话）识别前缀 'blah:' 和 'a:' 的等价性，但是 fn:in-scope-prefixes() 不会不显示“blah”，仅显示“a”。将上面的 行更改为：

<node><xsl:value-of select="in-scope-prefixes(.)"/></node>

输出：

<?xml version="1.0" encoding="UTF-8"?>
<node xmlns:blah="urn:schemas:blah:">xml a</node>

如何在不事先知道输入文件调用该前缀的情况下将输入前缀 'a' 映射到 'blah' '一个'？ （所以 对我不起作用。）

作为进一步的上下文，如果它指向更好的解决方案，那么这是为了查看外部生成的 XML 文档。外部进程使用自动生成的前缀“a:”、“b:”、“c:”等创建输入文档。我希望能够使用“友好”命名空间前缀显示这些前缀。

更新：in-scope-prefixes() 行为由 静态已知命名空间的定义

Answer 1

此转换（在 XSLT 1.0 和 XSLT 2.0 中均如此（只需更改 version 属性））：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my"
 >
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <my:namespaces>
    <ns prefix="blah" uri="urn:schemas:blah:"/>
    <ns prefix="foo" uri="uff:anotherNamespace"/>
  </my:namespaces>

  <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
 "*[namespace-uri()=document('')/*/my:namespaces/*/@uri]">
  <xsl:variable name="vNS" select=
  "document('')/*/my:namespaces/*
                   [@uri=namespace-uri(current())]"/>
  <xsl:element name="{$vNS/@prefix}:{local-name()}"
       namespace="{namespace-uri()}">
   <xsl:copy-of select=
    "namespace::*[not(. = namespace-uri(current()))]"/>
   <xsl:copy-of select="@*"/>
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

复制任何 XML 文档并仅替换此前缀文档用于选择具有我们指定的前缀的命名空间。

应用于此 XML 文档时：

<t>
    <a:node xmlns:a="urn:schemas:blah:"/>
    <b:node xmlns:b="urn:schemas:blah:"/>
    <c:node xmlns:c="uff:anotherNamespace"/>
</t>

生成所需结果：

<t>
   <blah:node xmlns:blah="urn:schemas:blah:"/>
   <blah:node xmlns:blah="urn:schemas:blah:"/>
   <foo:node xmlns:foo="uff:anotherNamespace"/>
</t>

Answer 2

身份转换加上这个模板怎么样：

<xsl:template match="blah:*">
  <xsl:element name="blah:{local-name()}">
    <xsl:apply-templates select="*|@*" />
  </xsl:element>
</xsl:template>

我不确定这是否是 XSLT 2.0 中最优雅的方法，但它确实有效。

Answer 3

查看 顶级元素的规范。我相信它会实现你想要的。