从 F# 中具有 N 个不同索引的序列中获取 N 个元素

Question

我是 F# 新手，正在寻找一个采用 N* 索引和序列并给我 N 个元素的函数。如果我有 N 个索引，它应该等于 concat Seq.nth index0, Seq.nth index1 .. Seq.nth indexN 但它应该只扫描序列中的 indexN 元素（O(N)），而不是 index0+index1+.. .+索引N (O(N^2))。

总而言之，我正在寻找类似的东西：

//For performance, the index-list should be ordered on input, be padding between elements instead of indexes or be ordered when entering the function
seq {10 .. 20} |> Seq.takeIndexes [0;5;10] 
Result: 10,15,20

我可以通过使用 seq { Yield... } 来实现这一点，并在应该传递某些元素时有一个索引计数器来标记，但如果 F# 提供了一个很好的标准方法，我会而是使用它。

谢谢:)...

补充：我做了以下内容。它有效，但不漂亮。欢迎提出建议

let seqTakeIndexes (indexes : int list) (xs : seq<int>) =
    seq {
        //Assume indexes is sorted
        let e = xs.GetEnumerator()
        let i = ref indexes 
        let curr = ref 0

        while e.MoveNext() && not (!i).IsEmpty do
            if !curr = List.head !i then
                i := (!i).Tail
                yield e.Current

            curr := !curr + 1
    }

Answer 1

当您想通过索引访问元素时，使用序列并不是一个好主意。序列被设计为允许顺序迭代。我会将序列的必要部分转换为数组，然后按索引选择元素：

let takeIndexes ns input = 
  // Take only elements that we need to access (sequence could be infinite)
  let arr = input |> Seq.take (1 + Seq.max ns) |> Array.ofSeq
  // Simply pick elements at the specified indices from the array
  seq { for index in ns -> arr.[index] }

seq [10 .. 20] |> takeIndexes [0;5;10]  

关于您的实现 - 我认为它不能变得更加优雅。在实现需要以交错方式从多个源获取值的函数时，这是一个普遍问题 - 只是没有优雅的方式来编写这些！

但是，您可以使用递归以函数式方式编写此代码，如下所示：

let takeIndexes indices (xs:seq<int>) = 
  // Iterates over the list of indices recursively
  let rec loop (xe:IEnumerator<_>) idx indices = seq {
    let next = loop xe (idx + 1)
    // If the sequence ends, then end as well
    if xe.MoveNext() then
      match indices with
      | i::indices when idx = i -> 
        // We're passing the specified index 
        yield xe.Current
        yield! next indices
      | _ -> 
        // Keep waiting for the first index from the list
        yield! next indices }
  seq {
    // Note: 'use' guarantees proper disposal of the source sequence
    use xe = xs.GetEnumerator()
    yield! loop xe 0 indices }

seq [10 .. 20] |> takeIndexes [0;5;10]  

Answer 2

当你需要扫描一个序列并在O(n)内累积结果时，你总是可以回退到Seq.fold：

let takeIndices ind sq =
    let selector (idxLeft, currIdx, results) elem =
        match idxLeft with
            | []                               -> (idxLeft, currIdx, results)
            | idx::moreIdx when idx =  currIdx -> (moreIdx, currIdx+1, elem::results)
            | idx::_       when idx <> currIdx -> (idxLeft, currIdx+1, results)
            | idx::_                           -> invalidOp "Can't get here."
    let (_, _, results) = sq |> Seq.fold selector (ind, 0, [])
    results |> List.rev

seq [10 .. 20] |> takeIndices [0;5;10]

这个解决方案的缺点是它会枚举序列到最后，即使如果它已经积累了所有所需的元素。

Answer 3

这是我的观点。该解决方案只会按照需要进入序列并以列表形式返回元素。

let getIndices xs (s:_ seq) =
    let enum = s.GetEnumerator()
    let rec loop i acc = function
        | h::t as xs ->
            if enum.MoveNext() then
                if i = h then
                    loop (i+1) (enum.Current::acc) t
                else
                    loop (i+1) acc xs
            else
                raise (System.IndexOutOfRangeException())
        | _ -> List.rev acc
    loop 0 [] xs

[10..20]
|> getIndices [2;4;8]
// Returns [12;14;18]

这里唯一的假设是您提供的索引列表是经过排序的。否则该功能将无法正常工作。

Answer 4

返回的结果是排序的，是不是有问题？
该算法将在输入序列上线性工作。只需要对索引进行排序即可。如果序列很大，但索引不是很多 - 它会很快。
复杂度为：N -> Max(索引), M ->索引数量：最坏情况下为 O(N + MlogM)。

let seqTakeIndices indexes = 
    let rec gather prev idxs xs =
        match idxs with
        | [] -> Seq.empty
        | n::ns ->  seq { let left = xs |> Seq.skip (n - prev)
                          yield left |> Seq.head
                          yield! gather n ns left }
    indexes |> List.sort |> gather 0

这是 List.fold 的变体，但阅读起来更复杂。我更喜欢第一个：

let seqTakeIndices indices xs = 
    let gather (prev, xs, res) n =
        let left = xs |> Seq.skip (n - prev)
        n, left, (Seq.head left)::res
    let _, _, res = indices |> List.sort |> List.fold gather (0, xs, [])
    res

附加：仍然比您的变体慢，但比我的旧变体快得多。由于不使用 Seq.skip 创建新的枚举器并且大大减慢了速度。

let seqTakeIndices indices (xs : seq<_>) = 
    let enum = xs.GetEnumerator()
    enum.MoveNext() |> ignore
    let rec gather prev idxs =  
        match idxs with
        | [] -> Seq.empty
        | n::ns -> seq { if [1..n-prev] |> List.forall (fun _ -> enum.MoveNext()) then 
                            yield enum.Current
                            yield! gather n ns }
    indices |> List.sort |> gather 0