gtkD：最小绘图示例？

Question

我是一位相当有经验的程序员，但对 GUI 编程还是个新手。我正在尝试将我为 DFL 编写的绘图库移植到 gtkD，但无法显示绘图。以下代码为我生成一个空白窗口。有人可以告诉我它有什么问题，和/或发布最小的示例代码来将几行放到 DrawingArea 上并在 MainWindow 中显示结果吗？

import gtk.DrawingArea, gtk.Main, gtk.MainWindow, gdk.GC, gdk.Drawable,
    gdk.Color;

void main(string[] args) {
    Main.init(args);

    auto win = new MainWindow("Hello, world");
    win.setDefaultSize(800, 600);
    auto drawingArea = new DrawingArea(800, 600);
    win.add(drawingArea);
    drawingArea.realize();

    auto drawable = drawingArea.getWindow();
    auto gc = new GC(drawable);
    gc.setForeground(new Color(255, 0, 0));
    gc.setBackground(new Color(255, 255, 255));
    drawable.drawLine(gc, 0, 0, 100, 100);

    drawingArea.showAll();
    drawingArea.queueDraw();
    win.showAll();

    Main.run();
}

Answer 1

我在 D 方面没有任何经验，但在 GTK 方面有很多经验，因此在 gtkD 教程的帮助下，我设法编写了一个最小的示例：

import gtk.DrawingArea, gtk.Main, gtk.MainWindow, gdk.GC, gdk.Drawable,
    gdk.Color, gtk.Widget;

class DrawingTest : MainWindow
{
    this()
    {
        super("Hello, world");
        setDefaultSize(800, 600);
        auto drawingArea = new DrawingArea(800, 600);
        add(drawingArea);
        drawingArea.addOnExpose(&drawStuff);
        showAll();
    }

    bool drawStuff(GdkEventExpose *event, Widget self) 
    {
        auto drawable = self.getWindow();
        auto gc = new GC(drawable);
        gc.setForeground(new Color(cast(ubyte)255, cast(ubyte)0, cast(ubyte)0));
        gc.setBackground(new Color(cast(ubyte)255, cast(ubyte)255, cast(ubyte)255));
        drawable.drawLine(gc, 0, 0, 100, 100);
        return true;
    }
}

void main(string[] args) {
    Main.init(args);
    new DrawingTest();
    Main.run();
}

在 GTK 中， DrawingArea 实际上只是一个空白的小部件进行绘制，并且在小部件上进行绘制必须始终在 expose-event 处理程序中完成。 （虽然我知道这会在 GTK 3 中改变！）

我知道你不能将函数连接为信号回调，只能连接委托，所以这就是 DrawingTest 类的原因。