XML/XSL 表格式

Question

假设我有一个包含 500 个 XML 标签名称的列表。我想使用 XSLT 在表格中显示此列表。在 XSLT 表中，我希望最多有三行；我不在乎我有多少列 - 我计划将表格放入可滚动的 div 中。如果我的姓名列表增长到 1,000，我仍然只需要三行，但列的数量可以增长到所需的任何大小。

我怎样才能在 XSLT 中做到这一点？就 XSL 表而言，我熟悉 xsl:for-each，但仅此而已。

格式是这样的：

<节点1> <节点2> <名称>数据< /名称> <名称>数据< /名称> ... < /节点2> < /节点1>

Answer 1

此转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pnumRows" select="3"/>

 <xsl:variable name="vnumCells" select="count(/*/*/NAME)"/>
 <xsl:variable name="vcellsPerRow"
       select="ceiling($vnumCells div $pnumRows)"/>


 <xsl:template match="node2">
  <table>
    <xsl:apply-templates select="NAME[position() mod $vcellsPerRow = 1]"/>
  </table>
 </xsl:template>

 <xsl:template match="NAME">
  <tr>
    <xsl:apply-templates mode="copy" select=
    ". | following-sibling::*[not(position() >= $vcellsPerRow)]"/>
  </tr>
 </xsl:template>

 <xsl:template match="NAME" mode="copy">
  <td><xsl:value-of select="."/></td>
 </xsl:template>
</xsl:stylesheet>

在具有指定格式的任何 XML 文档上执行时，如下所示：

<node1>
    <node2>
        <NAME>name1</NAME>
        <NAME>name2</NAME>
        <NAME>name3</NAME>
        <NAME>name4</NAME>
        <NAME>name5</NAME>
        <NAME>name6</NAME>
        <NAME>name7</NAME>
        <NAME>name8</NAME>
        <NAME>name9</NAME>
        <NAME>name10</NAME>
    </node2>
</node1>

产生所需的结果：包含三行的表格 ，其中前两行具有相同数量的单元格，最后一行可能更短：

    <table>
   <tr>
      <td>name1</td>
      <td>name2</td>
      <td>name3</td>
      <td>name4</td>
   </tr>
   <tr>
      <td>name5</td>
      <td>name6</td>
      <td>name7</td>
      <td>name8</td>
   </tr>
   <tr>
      <td>name9</td>
      <td>name10</td>
   </tr>
</table>

Answer 2

如果您正在讨论使用 XSLT 将 XML 转换为 HTML 表，我建议您查看 这篇文章。他提供了一些模板，允许您执行您正在谈论的操作，但可能需要进行一些调整。