如何在TCustomControls中添加TAboutBox？

Question

我想在我的自定义组件上添加 aboutbox/dialogbox。如何使小按钮[...]出现在对象检查器上？就像在 Timage 组件上分配图片一样。

Answer 1

您必须定义与此类似的属性：

//: Información acerca del paquete de componentes
property AboutMe:TFAbout read FAboutG stored false;

TFAbout 是一个类，定义当用户单击“对象检查器”中的属性时您想要看到的表单（关于表单）。

此外，如果您想看到带有三点 |...| 的按钮，则必须注册“属性编辑器”。在 OI 中。

这是一个示例单元：

unit UTAboutProp;

interface

uses
  DesignIntf, DesignEditors;

type
  TAboutGProp = class(TPropertyEditor)
  public
    procedure Edit(); override;
    function GetValue(): string; override;
    function GetAttributes(): TPropertyAttributes; override;
  end;

implementation

uses
  SysUtils, FormAbout, UConstantes;

procedure TAboutGProp.Edit();
begin
  with TFAbout.Create(nil) do
  try
    ShowModal();
  finally
    Free();
  end;
end;

function TAboutGProp.GetValue(): string;
begin
  result := Format(GLIBSI_LBL,[GLIBSI_VERSION]);
  result := '1.0';
end;

function TAboutGProp.GetAttributes(): TPropertyAttributes;
begin
  result := [paDialog,paReadOnly];
end;

end.

只需“注册”此“属性编辑器”即可使用您的“关于”属性；这对于将您的资源与您的编辑器“链接”起来非常重要。

在您有注册组件的代码的地方，添加注册属性的代码：

  RegisterPropertyEditor(TypeInfo(TFAbout),nil,'',TAboutGProp);

问候