在 perl 中转置

Question

我已经开始学习 perl 并喜欢尝试新事物。

我在文本处理方面遇到一些问题。 我有一些表格的文本，

0 1 2 3 4 5 6 7 8 9 10

6 7 3 6 9 3 1 5 2 4 6

我想转置该文本。就像，我想将行设置为列，将列设置为行。有没有办法在 Perl 中做到这一点？

谢谢大家。

Answer 1

所以这个解决方案使用数组的数组，每个嵌套数组
是一行数据。非常简单，您可以循环遍历每个中的列
行并使用列将它们推到另一个数组数组上
index 作为将值推送到的索引。这有效果
根据您的要求旋转数据。

#!/usr/bin/env perl

my @rows = ();
my @transposed = ();

# This is each row in your table
push(@rows, [qw(0 1 2 3 4 5 6 7 8 9 10)]);
push(@rows, [qw(6 7 3 6 9 3 1 5 2 4 6)]);

for my $row (@rows) {
  for my $column (0 .. $#{$row}) {
    push(@{$transposed[$column]}, $row->[$column]);
  }
}

for my $new_row (@transposed) {
  for my $new_col (@{$new_row}) {
      print $new_col, " ";
  }
  print "\n";
}

这导致：

0 6 
1 7 
2 3 
3 6 
4 9 
5 3 
6 1 
7 5 
8 2 
9 4 
10 6

Answer 2

以下概述了一种转置数据的方法。完成此示例将很有启发性，因为您将需要使用 CPAN，您将了解有用的 List::Util 和 List::MoreUtils 模块，您将学习复杂数据结构的基础知识（参见perlreftut, perldsc 和 perllol)，您将可以使用迭代器在 Perl 中。

use strict;
use warnings;
use List::MoreUtils qw(each_arrayref);

my @raw_data = (
    '0 1 2 3 4 5 6 7 8 9 10',
    '6 7 3 6 9 3 1 5 2 4 6',
);

my @rows = ... ; # Look up map() and split() to fill in the rest.
                 # You want an array of arrays.

my @transposed;  # You will build this in the loop below.

my $iter = each_arrayref(@rows);  # See List::MoreUtils documentation.

while ( my @tuple = $iter->() ){
    # Do stuff here to build up @transposed, which
    # will also be an array of arrays.
}

Answer 3

当然有，而且迈克指出了最简单的方法。如果您正在学习，您可能想编写自己的函数？
首先，您想要在空格上分割每一行以获得值数组（或推送 单词列表放入数组中，如 道尔顿的回答；在 Perl 中，做任何事情总是有不止一种方法）
然后，对于数组中的每个元素，您想要打印它及其第二个数组中的对应项放在同一行上。 （如果一个数组先于另一个数组耗尽，你会怎么做？）

当然，如果你想学习 Perl，你肯定也想学习使用 CPAN，所以使用 Data::Pivot 仍然值得尝试。

Answer 4

use strict;
# read the first line
my @labels = split ' ', <>;
# read and ignore the empty second line
<>;
# read the third line
my @values = split ' ', <>;
# transpose (I suppose you'll do more with the table than just printing it)
my %table = map { $labels[$_] => $values[$_] } 0..$#labels;
# print
foreach (@labels) {
    print "$_ $table{$_}\n";
}

Answer 5

这是我的新脚本，用于转置制表符分隔的文件。如果您愿意，请将 \t 更改为您的分隔符。

#!/usr/bin/perl -anF/\t|\n/
$n = @F - 1 if !$n;
for $i (0..$n) {
    push @{ $m->[$i] }, $F[$i];
}
END {
    for $r (@$m) {
        print join("\t", @$r), "\n";
    }
}

或者作为 104 个字符的“一行”（添加撇号-反斜杠-换行符-撇号以避免水平滚动）：

perl -anF'\t|\n' -e'$n=@F-1if!$n;for(0..$n){push@{$m[$_]},$F[$_]}'\
'END{print map{join"\t",@$_,"\n"}@$m}'

Answer 6

use List::UtilsBy qw/zip_by/;

my @transposition = zip_by { [ @_ ] } @matrix;

https://metacpan.org/pod/List::UtilsBy#zip_by

Answer 7

我在寻找一种方法来转置通过读取文件构建的 AoA 时遇到了这个问题，但是当然，这个解决方案仍然适用于任何 AoA，并且它不需要数组引用具有相同数量的元素。我知道这是一个老问题，但由于我仍在学习，如果有一些关于如何改进我的解决方案的批评/示例，那就太棒了。

my $max_rows = 0;
foreach my $line (@copy) {
    my $ref = ();
    push @$ref, split(/\s+/, $line);
    my $rows = scalar(@$ref);
    $aoa[$i] = \@$ref;
    $i++;
    if ($rows > $max_rows) {
        $max_rows = $rows;
    }
}

for (my $i = 0; $i <= $max_rows; $i++) {
    my @aoa_t = ();
    for (my $k = 0; $k <= $#aoa; $k++) {
        if ($aoa[$k]->[$i]) {
            push @aoa_t, $aoa[$k]->[$i];
        } else {
            push @aoa_t, " ";
        }
        print " @aoa_t\n";
    }
    if ($aoa_t[0] eq " ") {
        last;
    } else {
        $t_aoa[$i] = \@aoa_t;
    }
}

它对于包含 200 多行空格分隔格式数据的文件非常有效。如果本论坛适合的话，我们将不胜感激。问候。

Answer 8

Array-Transpose-0.06 怎么样？

http://metacpan.org/pod/Array::Transpose

Answer 9

use strict;
my ($i, $rows, $cols) = (0, 10, 100);
# initiate array 10x100
my $array = [map {[map {$i++} (1..$cols)]} (1..$rows)];
# transpose array into 100x10 array
my $transpose = [map {[map {shift @$_} @$array]} @{$array->[0]}];

数组必须是一个矩阵，即每行的列必须相等，原始数组将被破坏

此代码不会使用额外的内存进行转置，x2对于其他库，对于大型数组例如100x1M，这很重要