以用户身份运行我的程序

Question

Windows 7、Vista、Server 2008、UAC 已激活

程序必须具有管理员权限才能进行某些安装操作。之后，我希望我的程序能够继续以非管理员权限运行。

如何在没有管理权限的情况下重新启动它？

---

PS

我的程序会自行重新安装。我不想为其分发任何附加程序。所以我的步骤是：

1. 在临时目录中下载新版本
2. 在管理员权限下重新启动
3. 重命名旧的 exe 文件并从临时目录复制新的 exe 文件dir
4. 在非管理员权限下自行重启

Answer 1

在 UAC 下，现在强烈建议不要在“首次运行”时执行任何操作。此外，使用自行开发技术进行自我更新的程序会发现更加困难。您说您不想分发额外的程序，但在 UAC 下您实际上别无选择。要么你的整个应用程序每次都以提升的方式运行（惹恼用户），以防它碰巧需要执行一些管理操作，要么将其分成两部分，并偶尔运行一个提升的部分，而另一部分始终不提升。

拆分它的一种方法是编写一个安装程序，它可以提升，而常规应用程序则不能。这适用于安装一次、在第一次运行时执行一些操作（将这些操作移至安装程序）然后完成的人。你说你的应用程序会自行更新。因此，您需要将该代码移动到一个单独的 exe 中，并在该 exe 上放置一个包含 requireAdministrator 的清单。然后，当有新的更新可用时，您的主应用程序将启动（使用 ShellExecute）更新 exe。

Answer 2

感谢凯特·格雷戈里的帮助。

Delphi 上有一个工作代码：

function RunAsUser(CommandLine, WorkDirectory: string; Wait: Boolean): Boolean;
const
  TOKEN_ADJUST_SESSIONID = $0100;
  dwTokenRights = TOKEN_QUERY or TOKEN_ASSIGN_PRIMARY or TOKEN_DUPLICATE or TOKEN_ADJUST_DEFAULT or TOKEN_ADJUST_SESSIONID;
var
  WExe, WCmdLine, wCurrDir: WideString;
  hProcessToken, dwLastErr, retLength, hwnd, dwPID, hShellProcess, hShellProcessToken, hPrimaryToken: Cardinal;
  tkp: TOKEN_PRIVILEGES;
  PI: TProcessInformation;
  SI: TStartupInfoW;
begin
  Result:= False;

  hShellProcessToken:= 0;
  hPrimaryToken:= 0;
  hShellProcess:= 0;

  if WorkDirectory = '' then WorkDirectory:= GetCurrentDir;
  Wexe:= SeparateText(CommandLine, ' ');
  WCmdLine:= CommandLine;
  wCurrDir:= WorkDirectory;

    // Enable SeIncreaseQuotaPrivilege in this process.  (This won't work if current process is not elevated.)
    if not OpenProcessToken(GetCurrentProcess(), TOKEN_ADJUST_PRIVILEGES, hProcessToken) then Exit;

  tkp.PrivilegeCount:= 1;
  LookupPrivilegeValueW(nil, SE_INCREASE_QUOTA_NAME, tkp.Privileges[0].Luid);
  tkp.Privileges[0].Attributes:= SE_PRIVILEGE_ENABLED;
  AdjustTokenPrivileges(hProcessToken, FALSE, tkp, 0, nil, retLength);
  dwLastErr:= GetLastError();
  CloseHandle(hProcessToken);
  if (dwLastErr <> ERROR_SUCCESS) then Exit;

    // Get an HWND representing the desktop shell.
    // CAVEATS:  This will fail if the shell is not running (crashed or terminated), or the default shell has been
    // replaced with a custom shell.  This also won't return what you probably want if Explorer has been terminated and
    // restarted elevated.

    hwnd:= GetShellWindow();
  if hwnd = 0 then Exit;

  // Get the PID of the desktop shell process.
  GetWindowThreadProcessId(hwnd, dwPID);
  if dwPID = 0 then Exit;

  // Open the desktop shell process in order to query it (get the token)
  hShellProcess:= OpenProcess(PROCESS_QUERY_INFORMATION, FALSE, dwPID);
  if hShellProcess = 0 then Exit;

  // From this point down, we have handles to close, so make sure to clean up.
  try
    // Get the process token of the desktop shell.
    if not OpenProcessToken(hShellProcess, TOKEN_DUPLICATE, hShellProcessToken) then Exit;

    // Duplicate the shell's process token to get a primary token.
    // Based on experimentation, this is the minimal set of rights required for CreateProcessWithTokenW (contrary to current documentation).
    if not DuplicateTokenEx(hShellProcessToken, dwTokenRights, nil, SecurityImpersonation, TokenPrimary, hPrimaryToken) then Exit;

    SI.cb:= SizeOf(SI);
    FillChar(SI, SI.cb, 0);
    SI.wShowWindow:= SW_SHOWNORMAL;
    SI.dwFlags:= STARTF_USESHOWWINDOW;

    // Start the target process with the new token.
    Result:= CreateProcessWithTokenW(
      hPrimaryToken,
      0,
      PWideChar(WExe),
      PWideChar(wCmdLine),
      0,
      nil,
      PWideChar(wCurrDir),
      @si,
      @pi);

    if not Result then Exit;

    if Wait then
      while MsgWaitForMultipleObjects(1, PI.hProcess, False, INFINITE, QS_ALLINPUT) <> WAIT_OBJECT_0 do
        ProcessMessages;

    CloseHandle(PI.hProcess);
  finally
    // Clean up resources
    CloseHandle(hShellProcessToken);
      CloseHandle(hPrimaryToken);
    CloseHandle(hShellProcess);
  end;
end;

Answer 3

我认为你在这方面走错了路。我认为您应该执行以下操作之一：

• 在软件安装过程中执行安装操作，并要求安装具有管理员权限

，或者

• 以非管理员身份启动，并在需要执行某些操作时请求提升。这样您就不必重新启动程序。

编辑：
因此，步骤如下：

1. 检查新版本并在必要时下载
2. 提醒用户有新版本可用并请求提升 重
3. 命名/复制操作
4. 正常重新启动

请求提升无需重新启动。在 Vista 之前的环境中工作时，您可能仍希望使用这种方式。

Answer 4

这是一个简单的重启方法；

procedure Restart(RunAs: Boolean);
var
  i: Integer;
  Params: string;
begin
// Close handle to Mutex or any such thing if only one inst. is allowed

// Prepare to re-pass parameters if the application uses them
  Params := '';
  for i := 1 to ParamCount do
    Params := Params + ' "' + ParamStr(i) + '"';

  Application.MainForm.Close;
  Application.ProcessMessages;
  if RunAs then
    ShellExecute(0, 'runas', PChar(ParamStr(0)), PChar(Params), '', SW_SHOW)
  else
    ShellExecute(0, 'open', PChar(ParamStr(0)), PChar(Params), '', SW_SHOW);
end;