以编程方式对 Flex 列表组件的翻转指示器进行皮肤处理

Question

有谁知道如何将自定义翻转指示器皮肤添加到 Flex 3 列表组件中？ 它的 CSS 中没有 rolloveridicatorskin。

Answer 1

如果您只想更改所显示项目的背景和文本颜色，则 ListBase 类定义了以下样式：

• rollOverColor
  • 当用户将鼠标悬停在渲染器上时渲染器的背景颜色。
  • 默认值为0xEEFEE6。
• textRollOverColor
  • 当用户将鼠标悬停在渲染器上时，渲染器文本的颜色。
  • 默认值为 0x2B333C。

例如：

<mx:List rollOverColor="#FF0000" textRollOverColor="#FFFF00"/>

当您将鼠标移到某个项目上时，将在红色背景上显示黄色文本（！）。

Answer 2

这是代码。

package 
    {
        import flash.display.Graphics;
        import flash.display.Sprite;
        import flash.filters.DropShadowFilter;

        import mx.controls.List;
        import mx.controls.listClasses.IListItemRenderer;
        import mx.core.ClassFactory;


        public class friendList extends List
        {
            private var dropShadow:DropShadowFilter = new DropShadowFilter(2,117,0x000000,0.4);
            private var filtersArray:Array = new Array(dropShadow); 

           override protected function drawSelectionIndicator(indicator:Sprite, x:Number,
               y:Number, width:Number, height:Number, color:uint,
               itemRenderer:IListItemRenderer):void

           {

              var g:Graphics = Sprite(indicator).graphics;
              g.clear();
              g.beginFill(0x000000, 0.5);
              g.lineStyle(2,0xffffff,0.5);
              g.drawRoundRect(0, 0, width-2, height-2, 6);
              g.endFill();

              indicator.x = x;
              indicator.y = y;   
              indicator.filters = filtersArray;
           }
           override protected function drawHighlightIndicator(
                                    indicator:Sprite, x:Number, y:Number,
                                    width:Number, height:Number, color:uint,
                                    itemRenderer:IListItemRenderer):void
            {
                var g:Graphics = Sprite(indicator).graphics;
                g.clear();
                g.beginFill(0x163e76, 0.5);
                g.lineStyle(2,0xffffff,0.5);
                g.drawRoundRect(0, 0, width-2, height-2, 6);
                g.endFill();

                indicator.x = x;
                indicator.y = y;
                indicator.filters = filtersArray;
            }
       }
    }