当数据长度未知时，从 Perl 中的套接字接收数据的最佳方法是什么？

Question

现在，我在循环中一次读取一个字符，直到到达 \0 字符。有更好的方法吗？

Answer 1

将行结尾设置为 \x{00} (\0)，确保对其进行本地化，并在句柄上设置 getline，如下所示：

{
    local $/ = "\x{00}";
    while (my $line = $sock->getline) {
       print "$line\n"; # do whatever with your data here
   }
}

Answer 2

您可以将 FIONREAD 与 ioctl。下面的程序连接到本地主机上的 SSH 服务器并等待其问候语：

#! /usr/bin/perl

use warnings;
use strict;

use subs 'FIONREAD';
require "sys/ioctl.ph";
use Socket;
socket my $s, PF_INET, SOCK_STREAM, getprotobyname "tcp"
  or die "$0: socket: $!";
connect $s, sockaddr_in 22, inet_aton "localhost"
  or die "$0: connect: $!";

my $rin = "";
vec($rin, fileno($s), 1) = 1;
my $nfound = select my$rout=$rin, "", "", undef;
die "$0: select: $!" if $nfound < 0;

if ($nfound) {
  my $size = pack "L", 0;
  ioctl $s, FIONREAD, $size
    or die "$0: ioctl: $!";

  print unpack("L", $size), "\n";
  sysread $s, my $buf, unpack "L", $size
    or die "$0: sysread: $!";

  my $length = length $buf;
  $buf =~ s/\r/\\r/g;
  $buf =~ s/\n/\\n/g;
  print "got: [$buf], length=$length\n";
}

示例运行：

$ ./howmuch
39
got: [SSH-2.0-OpenSSH_5.3p1 Debian-3ubuntu4\r\n], length=39

但您可能更喜欢使用 IO::Socket::INET 和 IO::Select 模块，如下面与 Google 对话的代码：

#! /usr/bin/perl

use warnings;
use strict;

use subs "FIONREAD";
require "sys/ioctl.ph";
use IO::Select;
use IO::Socket::INET;

my $s = IO::Socket::INET->new(PeerAddr => "google.com:80")
  or die "$0: can't connect: $@";

my $CRLF = "\015\012";
print $s "HEAD / HTTP/1.0$CRLF$CRLF" or warn "$0: print: $!";

my @ready = IO::Select->new($s)->can_read;
die "$0: umm..." unless $s == $ready[0];

my $size = pack "L", 0;
ioctl $s, FIONREAD, $size
  or die "$0: ioctl: $!";

print unpack("L", $size), "\n";
sysread $s, my $buf, unpack "L", $size
  or die "$0: sysread: $!";

my $length = length $buf;
$buf =~ s/\r/\\r/g;
$buf =~ s/\n/\\n/g;
print "got: [$buf], length=$length\n";

输出：

573
got: [HTTP/1.0 200 OK\r\nDate: Sun, 18 Jul 2010 12:03:48 GMT\r\nExpires: -1\r\nCache-Control: private, max-age=0\r\nContent-Type: text/html; charset=ISO-8859-1\r\nSet-Cookie: PREF=ID=6742ab80dd810a95:TM=1279454628:LM=1279454628:S=ewNg64020FbnGzHR; expires=Tue, 17-Jul-2012 12:03:48 GMT; path=/; domain=.google.com\r\nSet-Cookie: NID=36=kn2wtTD4UJ3MYYQ5uvA4iAsrS2wcrb_W781pZ1hrVUhUDHrIJTMg_kOgVKhjQnO5SM6MdC_jrRdxFRyXwyyv5N3Xja1ydhVLWWaYqpMHQOmGVi2K5qRWAKwDhCVRd8WS; expires=Mon, 17-Jan-2011 12:03:48 GMT; path=/; domain=.google.com; HttpOnly\r\nServer: gws\r\nX-XSS-Protection: 1; mode=block\r\n\r\n], length=573

Answer 3

当数据长度未知时，从 Perl 套接字接收数据的最佳方法是什么？

对于任何语言来说，解决这个问题都是不可能的。如果您不知道数据长度有多长，那么您就不可能知道何时从套接字接收完所有数据。

您唯一的希望是使用某种指标来确定自数据开始进入以来是否“足够长”，以做出数据流已停止的决定。但它不会是完美的。

Answer 4

答案取决于协议。由于您的协议使用“\0”作为分隔符，因此您正在做正确的事情。我很确定 Perl 会为您处理缓冲，因此一次读取一个字符并不是低效的。

许多面向网络的协议在字符串之前都有一个长度。要读取这样的协议，您需要读取长度（通常是一个或两个字节，具体取决于协议规范），然后将那么多字节读入字符串中。

Answer 5

您可以使用 sysread 读取任何可用数据：

my $data;
my $max_length = 1000000;
sysread $sock, $data, $max_length;

Perl 的 read 函数等待您请求的完整字节数或 EOF。
这与 libc stdio fread(3) 类似。

Perl 的 sysread 函数一旦收到任何数据就会返回。
这类似于 UNIX read(2)。
请注意，sysread 会绕过缓冲 IO，因此请勿将其与缓冲 read 混合。

检查 perldoc -f read 和 perldoc -f sysread 了解更多信息。

对于这个具体问题，最好遵循最上面的答案，并使用 getline 和行尾 \0，但我们可以使用 sysread< /code> 如果没有终止字符。

这是一个小例子。它请求一个网页，并打印收到的第一块数据。

#!/usr/bin/perl -w
use strict; use warnings;
use IO::Socket;

my $host = $ARGV[0] || 'google.com';
my $port = $ARGV[1] || 80;
my $sock = IO::Socket::INET->new(Proto => 'tcp', PeerAddr => $host, PeerPort => $port)
    or die "connect failed: $!";
$sock->autoflush(1);
# use HTTP/1.1, which keeps the socket open by default
$sock->print("GET / HTTP/1.1\r\nHost: $host\r\n\r\n");
my $reply;
my $max_length = 1000000;
# $sock->read($reply, $max_length);   # read would hang waiting for 1000000 bytes
my $count = $sock->sysread($reply, $max_length);
if (!defined $count) {
    die "read failed: $!";
}
print $reply;