Tcl 匿名函数

Question

关于 Tcl 的纯理论问题。

在这个问题之后，我正在思考什么是最好的在Tcl中实现匿名函数的方法。

最终结果应该是允许开发人员将完整的过程作为参数传递给另一个过程：

do_something $data {proc {} {input} {
    puts $input;
}};

这与现在的 javascript 类似

do_something(data, function (input) {
    alert(input);
});

，当然这在 OOTB 中是行不通的。我正在思考这样的事情：

proc do_something {data anon_function} {
    anon_run $anon_function $data
}
proc anon_run {proc args} {
    set rand proc_[clock clicks];
    set script [lreplace $proc 1 1 $rand];
    uplevel 1 $script;
    uplevel 1 [concat $rand $args];
    uplevel 1 rename $rand {}; //delete the created proc
}

这可行。但我希望得到比这个更好的模式的建议，因为它不是很优雅，也没有真正使用很酷的 Tcl 功能。大多数情况下，我想摆脱手动调用anon_run。

Answer 1

在 Tcl 8.5 中，您可以使用 apply< /a> 命令。

proc do_something {data anon_function} {
    apply $anon_function $data
}
do_something $data {{input} {
    puts $input
}}

当然，如果您将回调构造为命令前缀（推荐！），那么您可以这样做：

proc lambda {arguments body} {
    # We'll do this properly and include the optional namespace
    set ns [uplevel 1 namespace current]
    return [list ::apply [list $arguments $body $ns]]
}

proc do_something {data command} {
    {*}$command $data
}

do_something $data [lambda {input} {
    puts $input
}]

如果您使用的是 8.4 或之前版本，则需要 来自 Tcler 维基的代码 作为替代，但请注意，这些解决方案仅在语义上等效（充其量）；它们的性能并不等同。