如何在替换中使用变量作为修饰符

Question

有没有办法在替换中使用变量作为修饰符？

my $search = 'looking';
my $replace = '"find: $1 ="';
my $modifier = 'ee';

s/$search/$replace/$modifier;

我需要使用哈希数组来使用不同的修饰符进行批量搜索替换。

Answer 1

虽然使用 eval 编译新替换的方法可能是最简单的，但您可以创建更加模块化的替换：

use warnings;
use strict;

sub subst {
    my ($search, $replace, $mod) = @_;

    if (my $eval = $mod =~ s/e//g) {
        $replace = qq{'$replace'};
        $replace = "eval($replace)" for 1 .. $eval;
    } else {
        $replace = qq{"$replace"};
    }
    sub {s/(?$mod)$search/$replace/ee}
}

my $sub = subst '(abc)', 'uc $1', 'ise';

local $_ = "my Abc string";

$sub->();

print "$_\n";  # prints "my ABC string"

这只是进行了轻微测试，并留给读者作为练习实现其他标志，例如 g

Answer 2

如果您戴上护目镜和除零服，则可以使用eval。

例如：

use strict;
use warnings;
sub mk_re {
  my ($search, $replace, $modifier) = @_;
  $modifier ||= '';
  die "Bad modifier $modifier" unless $modifier =~ /^[msixge]*$/;
  my $sub = eval "sub { s/($search)/$replace/$modifier; }";
  die "Error making regex for [$search][$replace][$modifier]: $@" unless $sub;
  return $sub;
}

my $search = 'looking';
my $replace = '"find: $1 ="';
my $modifier = 'e';

# Sub can be stored in an array or hash
my $sub = mk_re($search, $replace, $modifier);

$_ = "abc-looking-def";
print "$_\n";
$sub->();
print "$_\n";

Answer 3

嗯，如果我必须这样做，我会这样做：

use warnings;
use strict;
my @stuff = (
{
    search => "this",
    replace => "that",
    modifier => "g",
},
{
    search => "ono",
    replace => "wendy",
    modifier => "i",
}
);
$_ = "this ono boo this\n";
for my $h (@stuff) {
    if ($h->{modifier} eq 'g') {
        s/$h->{search}/$h->{replace}/g;
    } elsif ($h->{modifier} eq 'i') {
        s/$h->{search}/$h->{replace}/i;
    }
    # etc.
}
print;

您可能想要使用的不同修饰符只有这么多，所以我认为这很简单。

您可以使用 eval 来实现此目的，但它非常混乱。

Answer 4

当然 s/$search/$replace/ 按您的预期工作。动态修饰符并不简单。

对于pimsx的常规匹配修饰符，您可以使用Perl的扩展模式作为模式的一部分动态修改修饰符标志。它们的形式为 (?pimsx-imsx) 用于打开/关闭这些修饰符。

对于 s// e 和 ee 形式，您可以使用 (?{ perl code}) 中记录的相同的 perlre 部分。对于所有 eval e 或 ee 形式，请考虑结果代码的安全性！

据我所知，没有任何形式可以将全局修改为第一个匹配，因此全局与第一个匹配需要是单独的语句。

Answer 5

这是 Kinopiko 的回答和评估的组合。

这里使用eval以受控且可维护的方式生成查找表，查找表用于保存所有看起来不太好玩的if..elsif..elsif。

（经过非常简单的测试）

my @stuff = (
{
    search => "this",
    replace => "that",
    modifier => "g",
},
{
    search => "ono",
    replace => "wendy",
    modifier => "i",
}
);
$_ = "this ono boo this\n";

my @modifiers = qw{m s i x g e};

my $s_lookup = {};

foreach my $modifier (@modifiers) { 
    $s_lookup->{$modifier} =  eval " sub { s/\$_[0]/\$_[1]/$modifier } ";
}

for my $h (@stuff) {
    $s_lookup->{$h->{modifier}}->($h->{search},$h->{replace});
}

print; 

要完全有用，这需要：

1. 可能的修饰符组合
2. 在查找表上排序功能，以便“msi”组合和“mis”组合将转到相同的键。