绑定和闭合 groovy

Question

我不知道如何在 Groovy 中使用闭包绑定。我编写了一个测试代码，在运行它时，它说，在作为参数传递的闭包上缺少方法 setBinding 。

void testMeasurement() {
    prepareData(someClosure)
}
def someClosure = {
  assertEquals("apple", a)
}


  void prepareData(testCase) {
    def binding = new Binding()
    binding.setVariable("a", "apple")
    testCase.setBinding(binding)
    testCase.call()

  }

Answer 1

这适用于 Groovy 1.7.3：

someClosure = {
  assert "apple" == a
}
void testMeasurement() {
  prepareData(someClosure)
}
void prepareData(testCase) {
  def binding = new Binding()
  binding.setVariable("a", "apple")
  testCase.setBinding(binding)
  testCase.call()
}
testMeasurement()

在此脚本示例中，setBinding 调用在脚本绑定中设置 a （如您所见 来自 Closure 文档，没有 setBinding 调用）。因此，在 setBinding 调用之后，您可以调用

println a

它，它将打印出“apple”。

因此，要在类中执行此操作，您可以为闭包设置委托（当在本地找不到属性时，闭包将恢复为该委托）像这样：

class TestClass {
  void testMeasurement() {
    prepareData(someClosure)
  }

  def someClosure = { ->
    assert "apple" == a
  }

  void prepareData( testCase ) {
    def binding = new Binding()
    binding.setVariable("a", "apple")
    testCase.delegate = binding
    testCase.call()
  }
}

它应该从委托类（在本例中为绑定）中获取 a 的值

此页面详细介绍了闭包中委托的使用和变量的范围。

事实上，您不使用 Binding 对象，而是使用应该能够使用像这样的简单地图：

  void prepareData( testCase ) {
    testCase.delegate = [ a:'apple' ]
    testCase.call()
  }

希望有帮助！

Answer 2

这确实是奇怪的行为：删除 someClosure 声明前面的“def”使脚本在 JDK1.6 Groovy:1.7.3 中工作

更新：这是在上面的答案中发布的。我的错误是重复它。
更新：为什么它有效？如果没有 def，第一行将被视为属性分配，它调用 setProperty 并使变量在绑定中可用，稍后将进行解析。
def 应该 的效果与 (http:// /docs.codehaus.org/display/GROOVY/Groovy+Beans）

someClosure = {
    assert "apple", a
    print "Done"
}

void testMeasurement() {
    prepareData(someClosure)
}

void prepareData(testCase) {
    def binding = new Binding()
    binding.setVariable("a", "apple")
    testCase.setBinding(binding)
    testCase.call()
}
testMeasurement()

我可以通过以下代码重现您提到的问题。但我不确定这是否是使用绑定的正确方法。 GroovyDocs 表示它们将与脚本一起使用。您能否向我指出建议使用闭包绑定的文档。

class TestBinding extends GroovyTestCase {
    void testMeasurement() {
        prepareData(someClosure)
    }

    def someClosure = {
        assertEquals("apple", a)
    }

    void prepareData(testCase) {
        def binding = new Binding()
        binding.setVariable("a", "apple")
        //this.setBinding(binding)
        testCase.setBinding(binding)
        testCase.call()
    }
}

这在 groovy 邮件列表上得到了回答：

在脚本中，def foo 将创建一个局部变量，而不是一个属性
（私有字段+ getter/setter）。
将脚本想象为 run() 或 main() 方法的主体。
这就是定义局部变量的位置和方式。