在运行时使用 TRichEdit 而不定义父级

Question

我需要在运行时使用 TRichEdit 来执行 rtf 到文本的转换，如所讨论的 这里。我成功地做到了这一点，但我必须设置一个虚拟表单作为父表单，否则我无法填充 TRichedit.Lines。 （错误：父级丢失）。 我将我的函数粘贴在下面，任何人都可以建议一种避免定义父级的方法吗？您也可以对此发表评论并告诉我您是否找到了更高效的想法吗？

注意：我需要一个字符串，而不是 TStrings 作为输出，这就是它被设计成这样的原因。

function RtfToText(const RTF: string;ReplaceLineFeedWithSpace: Boolean): string;
var
  RTFConverter: TRichEdit;
  MyStringStream: TStringStream;
  i: integer;
  CustomLineFeed: string;

begin
  if ReplaceLineFeedWithSpace then
    CustomLineFeed := ' '
    else
    CustomLineFeed := #13;
  try
    RTFConverter := TRichEdit.Create(nil);
    try
      MyStringStream := TStringStream.Create(RTF);
      RTFConverter.parent := Form4; // this is the part I don't like
      RTFConverter.Lines.LoadFromStream(MyStringStream);
      RTFConverter.PlainText := True;
      for i := 0 to RTFConverter.Lines.Count - 1 do
      begin
        if i < RTFConverter.Lines.Count - 1 then
          Result := Result + RTFConverter.Lines[i] + CustomLineFeed
          else
          Result := Result + RTFConverter.Lines[i];
      end;
    finally
      MyStringStream.Free;
    end;
  finally
    RTFConverter.Free;
  end;

end;

更新： 回答后我更新了函数并写在这里供参考：

function RtfToText(const RTF: string;ReplaceLineFeedWithSpace: Boolean): string;
var
  RTFConverter: TRichEdit;
  MyStringStream: TStringStream;
begin
  RTFConverter := TRichEdit.CreateParented(HWND_MESSAGE);
  try
    MyStringStream := TStringStream.Create(RTF);
    try
      RTFConverter.Lines.LoadFromStream(MyStringStream);
      RTFConverter.PlainText := True;
      RTFConverter.Lines.StrictDelimiter := True;
      if ReplaceLineFeedWithSpace then
        RTFConverter.Lines.Delimiter := ' '
        else
        RTFConverter.Lines.Delimiter := #13;
      Result := RTFConverter.Lines.DelimitedText;
    finally
      MyStringStream.Free;
    end;
  finally
    RTFConverter.Free;
  end;
end;

Answer 1

TRichEdit 控件是 Windows 中 RichEdit 控件的包装器。 Windows 的控件是……嗯……Windows，它们需要一个窗口句柄才能工作。 Delphi 需要调用 CreateWindow 或 CreateWindowEx 来创建句柄，并且这两个例程都需要有效的父窗口句柄才能工作。 Delphi 尝试使用控件父级的句柄（这是有道理的！）。幸运的是，我们可以使用另一种构造函数（CreateParanted(HWND) 构造函数），并且 Microsoft 的优秀人员编写了 HWND_MESSAGE 来用作不支持该构造函数的窗口的父窗口。实际上需要一个“窗口”（仅消息传递）。

此代码按预期工作：

procedure TForm2.Button2Click(Sender: TObject);
var R:TRichEdit;
    L:TStringList;
begin
  R := TRichEdit.CreateParented(HWND_MESSAGE);
  try
    R.PlainText := False;
    R.Lines.LoadFromFile('C:\Temp\text.rtf');
    R.PlainText := True;

    Memo1.Lines.Text := R.Lines.Text;
  finally 
    R.Free;
  end;
end;

Answer 2

这是 VCL 工作方式的一部分，如果不采取一些繁重的解决方法，您将无法使其以不同的方式工作。但是您不需要定义一个虚拟表单作为父表单；只需使用您当前的表单并在 TRichEdit 上设置 visible := false; 即可。

不过，如果您确实想提高性能，则可以丢弃用于构建结果字符串的循环。它必须大量重新分配和复制内存。使用 TrichEdit.Lines 的 Text 属性在每行之间获取 CRLF，并使用 DelimitedText 获取其他内容，例如空格。它们使用仅分配一次的内部缓冲区，如果您正在处理大量文本，这将大大加快串联速度。

Answer 3

我使用 DrawRichText 在没有 RichEdit 控件的情况下绘制 RTF。 （IIRC 这称为无窗口富编辑控件.) 也许你也可以用它来转换 - 但我从来没有尝试过这个。

Answer 4

这对我开始使用 TRichEdit 来说是最有帮助的，但对转换却没有帮助。然而，这按预期工作，您不需要设置行分隔符：

// RTF to Plain:
procedure TForm3.Button1Click(Sender: TObject);
var
    l:TStringList;
    s:WideString;
    RE:TRichEdit;
    ss:TStringStream;
begin
    ss := TStringStream.Create;
    s := Memo1.Text; // Input String
    RE := TRichEdit.CreateParented(HWND_MESSAGE);
    l := TStringList.Create;
    l.Add(s);
    ss.Position := 0;
    l.SaveToStream(ss);
    ss.Position := 0;
    RE.Lines.LoadFromStream(ss);
    Memo2.Text := RE.Text; // Output String
end;

// Plain to RTF:
procedure TForm3.Button2Click(Sender: TObject);
var
    RE:TRichEdit;
    ss:TStringStream;
begin
    RE := TRichEdit.CreateParented(HWND_MESSAGE);
    RE.Text := Memo2.Text; // Input String
    ss := TStringStream.Create;
    ss.Position := 0;
    RE.Lines.SaveToStream(ss);
    ss.Position := 0;
    Memo1.Text := ss.ReadString(ss.Size); // Output String
end;

我在转换为普通文本时使用 TStringList“l”，因为 TStringStream 以某种方式将每个字符放入新行中。

编辑：使代码更好一点并删除未使用的变量。