如何在 Clojure 中为函数参数创建默认值

Question

我的想法是：

(defn string->integer [str & [base]]
  (Integer/parseInt str (if (nil? base) 10 base)))

(string->integer "10")
(string->integer "FF" 16)

但这一定是更好的方法。

Answer 1

如果签名的数量不同，则一个函数可以有多个签名。您可以使用它来提供默认值。

(defn string->integer 
  ([s] (string->integer s 10))
  ([s base] (Integer/parseInt s base)))

请注意，假设 false 和 nil 都被视为非值，(if (nil? base) 10 base) 可以缩短为 （如果基数为 10），或进一步到（或基数 10）。

Answer 2

从 Clojure 1.2 开始，您还可以将 rest 参数解构为映射 [ref ]。这使您可以命名并提供函数参数的默认值：

(defn string->integer [s & {:keys [base] :or {base 10}}]
    (Integer/parseInt s base))

现在您可以调用

(string->integer "11")
=> 11

或

(string->integer "11" :base 8)
=> 9

您可以在此处查看其实际效果：https://github.com/Raynes/clavatar/blob/master/src/clavatar/core.clj （例如）

Answer 3

这个解决方案更接近原始解决方案的精神，但稍微干净

(defn string->integer [str & [base]]
  (Integer/parseInt str (or base 10)))

一点类似模式，可以方便地使用或与let

(defn string->integer [str & [base]]
  (let [base (or base 10)]
    (Integer/parseInt str base)))

虽然在这种情况下更详细，但如果您希望默认值依赖于其他输入值，它可能会很有用。例如，考虑以下函数：

(defn exemplar [a & [b c]]
  (let [b (or b 5)
        c (or c (* 7 b))]
    ;; or whatever yer actual code might be...
    (println a b c)))

(exemplar 3) => 3 5 35

这种方法也可以轻松扩展以使用命名参数（如 M. Gilliar 的解决方案）：

(defn exemplar [a & {:keys [b c]}]
  (let [b (or b 5)
        c (or c (* 7 b))]
    (println a b c)))

或者使用更多的融合：

(defn exemplar [a & {:keys [b c] :or {b 5}}]
  (let [c (or c (* 7 b))]
    (println a b c)))

Answer 4

您可能需要考虑另一种方法：部分函数。这些可以说是一种更“实用”且更灵活的指定函数默认值的方式。

首先创建（如有必要）一个函数，该函数具有您想要提供的默认参数作为前导参数：

(defn string->integer [base str]
  (Integer/parseInt str base))

这样做是因为 Clojure 的 partial 版本允许您仅按照它们在函数定义中出现的顺序提供“默认”值。根据需要对参数进行排序后，您可以使用 partial 函数创建该函数的“默认”版本：

(partial string->integer 10)

为了使该函数可多次调用，您可以使用以下命令将其放入 var 中： def：

(def decimal (partial string->integer 10))
(decimal "10")
;10

您还可以使用 let 创建“本地默认值”：

(let [hex (partial string->integer 16)]
  (* (hex "FF") (hex "AA")))
;43350

与其他方法相比，部分函数方法有一个关键优势：消费者的消费者函数仍然可以决定默认值，而不是函数的生产者，无需修改函数定义。这在 hex 示例中进行了说明，其中我确定默认函数 decimal 不是我想要的。

这种方法的另一个优点是您可以为默认函数分配不同的名称（十进制、十六进制等），这可能更具描述性和/或不同的范围（var、local）。如果需要，部分函数也可以与上述一些方法混合使用：（

(defn string->integer 
  ([s] (string->integer s 10))
  ([base s] (Integer/parseInt s base)))

(def hex (partial string->integer 16))

请注意，这与 Brian 的答案略有不同，因为由于本响应顶部给出的原因，参数的顺序已被颠倒）

Answer 5

您还可以查看 (fnil) https://clojuredocs.org/clojure。核心/fnil

Answer 6

与 Matthew 的建议非常相似的方法是不执行 & 剩余参数，而是要求调用者提供灵活（和可选）键的单个额外映射参数。

(defn string->integer [s {:keys [base] :or {base 10}}]
    (Integer/parseInt s base))

(string->integer "11" {:base 8})
=> 9

(string->integer "11" {})
=> 11

这样做的一个好处是，选项是单个参数映射，调用者不必如此小心地传递偶数个额外参数。另外，短绒可以用这种风格做得更好。编辑器还应该在映射键值表格对齐（如果您喜欢的话）方面做得比每行参数对更好。

轻微的缺点是，当在没有选项的情况下调用时，仍然必须提供一个空地图。

位置参数部分（Code Smells 文章）对此进行了讨论。

更新： Clojure 1.11 现在支持 传入可选参数的映射（使用&）。