如何在 Excel 2007 VBA 中以编程方式冻结 Excel 工作表的顶行？

Question

我希望通过 VBA 以编程方式冻结 Excel 工作表的顶行。最终目标是产生与 View > 相同的效果。冻结窗格> Excel 2007 中的“冻结顶行”命令可以冻结工作表的顶行，用户即使在滚动数据时也可以看到工作表的顶行。

Answer 1

Rows("2:2").Select
ActiveWindow.FreezePanes = True

选择不同的范围以获得不同的效果，与手动操作的方式非常相似。 “冻结顶行”实际上只是 Excel 2007（及更高版本）中新增的快捷方式，与早期版本的 Excel 相比，它不包含任何附加功能。

Answer 2

Tomalak 已经给了您正确的答案，但我想补充一点，大多数时候，当您想知道在用户界面中执行特定操作所需的 VBA 代码时，记录宏是一个好主意。

在这种情况下，单击功能区开发人员选项卡上的“录制宏”，冻结顶行，然后停止录制。 Excel 将为您录制以下宏，它也可以完成这项工作：

With ActiveWindow
    .SplitColumn = 0
    .SplitRow = 1
End With
ActiveWindow.FreezePanes = True

Answer 3

录制的宏的问题与内置操作的问题相同：Excel 选择冻结顶部可见行，而不是可以找到标题信息的实际顶行。

在这种情况下，宏的目的是冻结实际的顶行。当我查看行 #405592 时，我需要检查该列的标题（因为我在打开文件时忘记冻结行），我必须滚动到顶部，冻结顶行，然后找到返回的方式再次行#405592。因为我认为这是愚蠢的行为，所以我想要一个宏来纠正它，但是，就像我说的，录制的宏只是模仿同样的愚蠢行为。

我正在使用 Office 2011 for Mac OS X Lion

更新（2 分钟后）：

我在这里找到了解决方案：http ://www.ozgrid.com/forum/showthread.php?t=19692

Dim r As Range 
Set r = ActiveCell 
Range("A2").Select 
With ActiveWindow 
    .FreezePanes = False 
    .ScrollRow = 1 
    .ScrollColumn = 1 
    .FreezePanes = True 
    .ScrollRow = r.Row 
End With 
r.Select 

Answer 4

刚刚遇到同样的问题...
由于某种原因，freezepanes 命令只会导致十字准线出现在屏幕中央。原来我已经关闭了 ScreenUpdating！
使用以下代码解决：

Application.ScreenUpdating = True
Cells(2, 1).Select
ActiveWindow.FreezePanes = True

现在工作正常。

Answer 5

将这个问题扩展到 Excel 之外的使用领域
自己的 VBA，ActiveWindow 属性 必须作为 Excel.Application 对象 的子对象进行寻址。

从 Access 创建 Excel 工作簿的示例：

在另一个 Office 应用程序中使用 Excel.Application 对象 VBA 项目将要求您添加 Microsoft Excel 15.0 对象库（或您自己版本的等效库）。

Option Explicit

Sub xls_Build__Report()
    Dim xlApp As Excel.Application, ws As Worksheet, wb As Workbook
    Dim fn As String

    Set xlApp = CreateObject("Excel.Application")
    xlApp.DisplayAlerts = False
    xlApp.Visible = True

    Set wb = xlApp.Workbooks.Add
    With wb
        .Sheets(1).Name = "Report"
        With .Sheets("Report")

            'report generation here

        End With

        'This is where the Freeze Pane is dealt with
        'Freezes top row
        With xlApp.ActiveWindow
            .SplitColumn = 0
            .SplitRow = 1
            .FreezePanes = True
        End With

        fn = CurrentProject.Path & "\Reports\Report_" & Format(Date, "yyyymmdd") & ".xlsx"
        If CBool(Len(Dir(fn, vbNormal))) Then Kill fn
        .SaveAs FileName:=fn, FileFormat:=xlOpenXMLWorkbook
    End With

Close_and_Quit:
    wb.Close False
    xlApp.Quit
End Sub

核心过程实际上只是重复以前提交的答案，但我认为演示当您不在 Excel 自己的 VBA 中时如何处理 ActiveWindow 很重要。虽然这里的代码是VBA，但它应该可以直接转录为其他语言和平台。

Answer 6

Rows("2:2").Select
ActiveWindow.FreezePanes = True

这是冻结顶行的最简单方法。 FreezePanes 的规则是它将冻结您所选单元格的左上角。例如，如果您突出显示 C10，它将冻结在 B 列和 C 列、第 9 行和第 10 行之间。因此，当您突出显示第 2 行时，它实际上冻结在第 1 行和第 2 行（顶行）之间。

另外，一旦您解冻窗口， .SplitColumn 或 .SplitRow 就会分割您的窗口，这不是我喜欢的方式。