即使我已将 DBI 调用包装在 eval 中，为什么我仍会在控制台上看到 DBI 错误？

Question

我有一个在 eval 中运行的数据库查询，以捕获错误。问题是错误消息正在输出到控制台，即使它被捕获。当我想自己解析它并吐出我自己的消息时，如何阻止错误消息这样做？

my $dbh = DBI->connect('dbi:Pg:dbname=database;host=localhost',
    'user', 'pass', 
    {RaiseError => 1}
);

eval{
    $sth = $dbh->prepare($sql);
    $sth->execute;
};

if($@){
    #Do my parse/print stuff here I know
}

Answer 1

捕获和忽略错误都不是一个好主意，无论它们是否致命。另外，不建议以您正在执行的方式检查 $@ （请参阅本网站上有关 perl 异常的问题，以获取捕获异常的更好方法；我使用 Try::Tiny 下面，这可以说是最轻量级的路线）。

当先前的操作可能失败时，您不应继续执行 DBI 操作，而应在每一步检查错误条件：

use strict; use warnings;
use Try::Tiny;

try {
    my $sth = $dbh->prepare($sql) or die $dbh->errstr;
    $sth->execute or die $sth->errstr;
} catch {
    print "got error $_\n";
    # return from function, or do something else to handle error
};

并记住，始终 使用严格；在每个模块和脚本中使用警告；。您的代码摘录表明您尚未执行此操作。

Answer 2

您可以指定 'PrintError => 0' 在您的 connect 调用中（或使用 HandleError )：

my $dbh = DBI->connect('dbi:Pg:dbname=database;host=localhost', $user, $passwd, {
  PrintError => 0,
  RaiseError => 1,
});

或者设置每个语句句柄：

my $sth = $dbh->prepare("SELECT * from my_table");
$sth->{PrintError} = 0;
$sth->execute();
...etc.

另外，不要依赖 $@ 来指示错误。使用 eval 的更好方法是：

my $result = eval {
  ...
  $sth->...etc.
  1;
}
unless ($result) {
  # Do error handling..log/print $@
}

Answer 3

eval { } 将捕获致命错误（来自 die 或 Carp::croak 调用），但不会捕获非致命错误消息（来自 warn 或 carp）。要处理警告消息，请参阅 %SIG< 的文档中如何安装警告处理程序/code>或 警告。

一个简单的解决方法是在您的 eval 块中使用一个简单的警告处理程序。

eval {
    local $SIG{__WARN__} = sub { };
    ...
};

另请参阅：perlfaq7：如何暂时阻止警告？