从 Flex 下载作为文件发布到服务器的数据

Question

这应该是微不足道的，而且我很确定我以前做过一次。

我正在尝试将数据发布到服务器，并将其作为文件下载反弹给我，从而提示本机浏览器文件下载框。我知道服务器部分工作得很好，因为我可以从演示 Web 表单发布，但是当我运行以下 Flex 3 代码时，我什至无法触发请求。

var fileRef:FileReference = new FileReference();
private function saveXmlAsFile(event:MouseEvent):void
{                           
    var fileRequest:URLRequest = new URLRequest();
    fileRequest.method = URLRequestMethod.POST;
    fileRequest.url = "http://foo.com/dataBounce";

    var urlVariables:URLVariables = new URLVariables();             
    urlVariables.content = "Test content to return" ; 
    // fileRequest.contentType = "application/x-www-form-urlencoded ";

    urlVariables.fileName = "test.xml";

    fileRef.addEventListener(SecurityEvent.ALL, onSecurityError);
    fileRef.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError2);
    fileRef.addEventListener(IOErrorEvent.NETWORK_ERROR, onNetworkError);
    fileRef.addEventListener(Event.COMPLETE, onComplete);

    try
    {
        fileRef.download(fileRequest, "test.xml");
    }catch(error:Error) {
        model.logger.error("unable to download file");
    }       
}

请注意，当调用 fileRef.download 时，我看不到使用传统 Firebug 或 HTTPWatch 浏览器工具通过网络发出的任何请求。

编辑：我应该补充一点，这是针对 < Flash Player 10，因此我无法使用较新的直接另存为文件功能。

有什么建议吗？谢谢。

Answer 1

您需要添加 fileRef.upload 来触发上传。

另外，我会将下载语句移至 onComplete ，以便在上传文件之前不会请求该文件。

Answer 2

你的解释很清楚，但是当我看你的代码时，我觉得我错过了一些东西。

该代码看起来像是您正在尝试执行一半的上传部分和一半的下载部分。

我认为如果您将 .method 值设置为 GET，您当前发布的代码将可以触发下载。我相信您还需要将文件名作为 .url 属性的一部分包含在内。

但是，要发布某些内容然后触发其下载，您需要两个单独的操作 - 发布数据的操作和下载数据的操作，这可能应该从上传操作的 onComplete 处理程序中调用。

Answer 3

好吧，我相信我已经弄清楚了正在发生的事情之一。

当您未设置 URLRequest.data 属性时，它将默认请求方法为“GET”。

因此，工作代码看起来像这样，将数据设置为发布的 URL 变量：

private var fileRef:FileReference;
private function saveRawHierarchy(event:MouseEvent):void
{                                   
    var fileRequest:URLRequest = new URLRequest();
    fileRequest.method = URLRequestMethod.POST;
    fileRequest.url = "http://foo/bounceback";

    var urlVariables:URLVariables = new URLVariables();             
    urlVariables.content = "CONTENT HERE";
    urlVariables.fileName = "newFileName.xml";

    fileRequest.data = urlVariables;

    fileRef = new FileReference();                   
    fileRef.addEventListener(Event.COMPLETE, onComplete); 

    try
    {
        fileRef.download(fileRequest, "appHierarchies.xml");
    }catch(error:Error) {
        model.logger.error("unable to download file");
    }       
}

不过，不确定之前未发出的请求出了什么问题。