将 XML 文件转换为可由 VCS 人工编辑和管理的文件

Question

有时 XML 文件需要存储在某些 VCS 中。此类文件通常使用 GUI 工具进行编辑，这些工具可以根据需要每次对元素重新排序。

此外，VCS 合并通常是面向行的，并且通常 XML 文件要么看起来像一长行，要么像 那样完全缩进

<foo>
    <bar>
        <name>
            n3
        </name>
        <value>
            qqq3
        </value>
    </bar>
    <bar>
        <name>
            n2
        </name>
        <value>
            qqq2
        </value>
    </bar>
</foo>

，而它们应该看起来像

<foo>
    <bar>  <name> n2 </name>  <value> qqq2 </value> </bar>
    <bar>  <name> n3 </name>  <value> qqq3 </value> </bar>
</foo>

（例如“部分缩进”）以便更易于人类阅读/编辑、紧凑。一个简单的逻辑单元应该占据一行。

即使有人将 XML 文件转换为如此好的格式，其他人也会在 GUI 工具中对其进行编辑，该工具将重新排序并重新意图所有内容，这将是很糟糕的（不可读，VCS 将报告大量更改，尽管几乎没有实际更改）。

是否有现成的 XSLT 转换（或其他程序）将所有 XML 文件转换为某种统一格式（例如排序（如果元素顺序不重要）并统一空格）以及我可以在哪里指定哪些元素应该是 oneliners？

例如，如果我可以在 .gitattributes 中指定过滤器这样的转换，那么 git 会自动处理这个问题。

Answer 1

我没有在每个 XSLT 处理器中进行测试（事实上，我只在 MSXSL 中进行了测试）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes"/>
    <xsl:template match="@*|node()" name="identity">
        <xsl:if test="self::bar">
            <xsl:text>
</xsl:text>
        </xsl:if>
        <xsl:copy>
            <xsl:apply-templates select="@*|node()">
            <xsl:sort select="normalize-space(name)"/>
            </xsl:apply-templates>
            <xsl:if test="self::foo">
                <xsl:text>
</xsl:text>
            </xsl:if>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="text()">
        <xsl:value-of select="normalize-space(.)"/>
    </xsl:template>
</xsl:stylesheet>

结果：

<foo>
<bar><name>n2</name><value>qqq2</value></bar>
<bar><name>n3</name><value>qqq3</value></bar>
</foo>

注意：XML 序列化可能会有所不同。如果是这种情况，请保留逻辑并序列化为 TEXT（您必须通过输出开始和结束标记以及属性来模拟 XML 序列化）

编辑：进行较小的更改，以便正确对不同的序列化输入进行排序。

Answer 2

是的，有 XML 漂亮的打印机；我自己总是使用 xmllint 。

Answer 3

基于 http://www.dpawson.co 创建了我自己的排序缩进器。 uk/xsl/sect2/pretty.html 和 Alejandro 的答案：http://vi -server.org/vi/sortindent.xsl。镜像如下：

<!-- Change 'oneliner' to the name of element you want to see as one line -->
<!-- Remove 'xsl:sort' element if you don't want sorting -->
<!-- http://stackoverflow.com/questions/3157658/converting-xml-files-to-be-human-editable-and-managable-by-vcs/3160818#3160818 -->

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml"/>
   <xsl:param name="indent-increment" select="'   '" />

   <xsl:template match="*">
      <xsl:param name="skip_indent" select="name()='oneliner' or name()='another_oneliner'"/> 
      <xsl:param name="indent" select="'
'"/>

      <xsl:if test="not($skip_indent)">
      <xsl:value-of select="$indent"/>

      <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates>
        <xsl:with-param name="indent" select="concat($indent, $indent-increment)"/>
        <xsl:sort select="@*|node()"/> 
        </xsl:apply-templates>
        <xsl:if test="*">
          <xsl:value-of select="$indent"/>
        </xsl:if>

      </xsl:copy>

      </xsl:if>
      <xsl:if test="$skip_indent">
         <xsl:value-of select="$indent"/>
         <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates>
           <xsl:with-param name="indent" select="' '"/>
           <xsl:with-param name="skip_indent" select="1"/>
           <xsl:sort select="@*|node()"/> 
            </xsl:apply-templates>
         </xsl:copy>
      </xsl:if>
   </xsl:template>

   <xsl:template match="comment()|processing-instruction()">
      <xsl:copy />
   </xsl:template>

   <xsl:template match="text()">
       <xsl:param name="skip_indent" select="0"/> 
       <xsl:if test="$skip_indent">
           <xsl:value-of select="normalize-space(.)"/>
       </xsl:if>
       <xsl:if test="not($skip_indent)">
           <xsl:if test="not(normalize-space(.)='')">
              <xsl:value-of select="."/>
           </xsl:if>
       </xsl:if>
   </xsl:template>


</xsl:stylesheet>

现在，原始 XML 文件的“等效”转换（属性的重新排序除外）映射到相同的结果 XML，并且格式良好，并且我可以强制某些元素成为单行元素。