在 emacs 中移动区域或行

Question

我正在 emacs 中寻找一种将文本向右或向左移动 n 个空格的方法。与 vim << 或 >> 中的功能类似。它应该在一个区域上工作，或者如果当前行上没有选择任何区域，并且不会将光标从当前位置移动。

EmacsWiki 的解决方案效果不如 Mx indent-rigidly 因为它会记住最后使用的区域并移动该区域。最接近的似乎是这里，但我没能做到让它发挥作用。我不是 Lisp 开发人员，因此很难修改代码。我将不胜感激任何帮助。

谢谢！

Answer 1

您可以选择区域，然后 Cu Cx 将移动 4 个空格。您可以在 Cu 后面键入一个数字，将 4 更改为其他任何值。

Answer 2

也许这会按照你想要的方式工作。

(defun shift-text (distance)
  (if (use-region-p)
      (let ((mark (mark)))
        (save-excursion
          (indent-rigidly (region-beginning)
                          (region-end)
                          distance)
          (push-mark mark t t)
          (setq deactivate-mark nil)))
    (indent-rigidly (line-beginning-position)
                    (line-end-position)
                    distance)))

(defun shift-right (count)
  (interactive "p")
  (shift-text count))

(defun shift-left (count)
  (interactive "p")
  (shift-text (- count)))

Answer 3

为了实现这一点，我通常会采取一个技巧：

• 激活 CUA 模式，
• 转到 C-RET 行的开头
• ，现在如果移动光标，您应该会看到一个矩形红色区域
• 将光标向下移动并键入空间，直到获得正确的变速。

这也可以通过某种方式（以相同的方式）以编程方式完成。

编辑：
我刚刚读过 emacs wiki 中的文章，它是相同的解决方案，除了 CUA 模式，它比“常见”矩形选择（因为它是可视的）更强大。

Answer 4

当我使用 Evil （与 Doom Emacs），类似 Vim 的区域移动已经在邪恶的视觉模式中通过 Sv 和 </ 实现> 正确。

不过，我主要使用插入模式，当它处于活动状态时，我也希望能够移动区域，最好是通过当前语言的移动宽度。

为了实现这一目标，这里有一个重新使用邪恶转移的实现，但在插入模式中“正确”地实现了它。

(defun jj/shift-text (beg end shift-block-fun shift-line-fun)
  "shift text in region or line using evil like S-v with < and > do in Vim.
  It takes special care of preserving or even extending the region to the moved text lines."
  (if (use-region-p)
      (progn
        (let ((point-at-end (< (mark) (point))))

          ;; fix up current region end to grab the whole line
          (if point-at-end
              (end-of-line)
            (beginning-of-line))

          ;; then fix up the other region end
          (exchange-point-and-mark)
          (if point-at-end
              (beginning-of-line)
            (end-of-line))

          ;; restore mark-point order
          (exchange-point-and-mark)

          (let ((linebeg (if point-at-end (mark) (point)))
                (lineend (if point-at-end (point) (mark))))
            ;; shift the text
            (save-mark-and-excursion
              (funcall shift-block-fun linebeg lineend)
              ;; "In Transient Mark mode, every buffer-modifying primitive sets deactivate-mark"
              ;; but we wanna keep it active :)
              (setq deactivate-mark nil)))))

    (funcall shift-line-fun 1)))

(defun jj/shift-left (beg end)
  (interactive "r")
  (jj/shift-text beg end #'evil-shift-left #'evil-shift-left-line))

(defun jj/shift-right (beg end)
  (interactive "r")
  (jj/shift-text beg end #'evil-shift-right #'evil-shift-right-line))

以及定义键绑定的位置：

  ;; text shifting. evil-normal-state-map has these anyway.
  (define-key evil-hybrid-state-map (kbd "M-<") #'jj/shift-left)
  (define-key evil-hybrid-state-map (kbd "M->") #'jj/shift-right)