在Scheme中的List中添加一个元素

Question

下面是我的代码，它采用列表(carVal) 的 car 元素和列表（初始化为空）作为参数。我想将元素追加到列表中，但同样不起作用。

(define populateValues
   (lambda (carVal currVal)
      (append currVal(list carVal ))
       (display currVal)))

显示屏始终显示空列表 () 。谁能帮我理解为什么？

Answer 1

好吧，有 append! 作为一个原语，它解决了你的大部分问题，正如已经指出的，Scheme 倾向于不赞成突变，这是可能的，但通常会避免，所以所有突变的过程都有一个! （称为“爆炸”）在其末尾。

另外，set! 不会改变数据，它会改变环境，它使变量指向另一个事物，原始数据保持不变。

在Scheme中改变数据是相当麻烦的，但是，给你我自己的append实现！看看它是如何完成的：

(define (append! lst . lsts)
  (if (not (null? lsts))
      (if (null? (cdr lst))
          (begin
            (set-cdr! lst (car lsts))
            (apply append! (car lsts) (cdr lsts)))
          
          (apply append! (cdr lst) lsts))))

注意 set-cdr! 的使用，它是一个真正的变异器，它只对成对起作用，它会改变内存中的数据，与“set!”不同。如果将一对传递给函数并使用 set-cdr 进行变异！或 set-car!，它在程序中的每个地方都发生了变化。

这遵循 SRFI 附录！例如，规范规定它应该是可变的，并且应该返回一个未定义的值。

(define l1 (list 1 2 3 4))

(define l2 (list 2 3 4))

(define l3 (list 3 1))

(append! l1 l2 l3)

l1

l2

l3

显示：

(1 2 3 4 2 3 4 3 1)
(2 3 4 3 1)
(3 1)

如可见，追加！可以接受无限多个参数，并且它会改变除最后一个之外的所有参数。

不过，Scheme 可能不是您的理想语言。使用追加！正如之前所说，这是非标准的，相反，append 是首选，它不会发生变化，并且会被调用以获取其返回值。我是这样实现的：

(define (append . lsts)
  (cond
    ((null? lsts) '())
    ((null? (car lsts)) (apply append (cdr lsts)))
    (else (cons (caar lsts) (apply append (cdar lsts) (cdr lsts))))))


> (append (list 1 2 3) (list 4 5 6) (list 'reasonable 'behavior))
(1 2 3 4 5 6 reasonable behavior)

在没有突变、大量使用递归的情况下，它显示了更熟悉的方案风格
并且不使用测序。

编辑：如果您只想将一些元素添加到列表中，而不是本身加入两个元素：

(define (extend l . xs)
  (if (null? l) 
      xs
      (cons (car l) (apply extend (cdr l) xs))))

(define (extend! l . xs)
  (if (null? (cdr l))
      (set-cdr! l xs)
      (apply extend! (cdr l) xs)))

(extend '(0 1 2 3) 4 5 6)

(define list1 '(0 1 2 3))

(extend! list1 4 5 6)

list1

这符合您的期望

Answer 2

1. append 创建一个新列表，它不会修改现有列表。
2. 这是因为一般来说，Scheme（以及本例中的 Racket）是一种更喜欢函数式风格的语言。
3. 您可以使用 set! 来更接近——但即使这样也会让您失望，因为它只会修改本地绑定。
4. 请注意，特别是在 Racket 中，列表是不可变的，因此没有任何东西可以更改列表。
5. 此外，即使您可以通过这种方式修改列表，这也是累积长列表的一种非常低效的方法，因为您必须重复扫描整个列表。
6. 最后，如果您在这个级别遇到问题，那么我强烈建议您查看 HtDP

Answer 3

(append foo bar) 返回 foo 和 bar 的串联。它不会更改 foo 或 bar。

Answer 4

您必须使用 set! 更新 currVal 的值。你的例子应该有

(set! currVal (append currVal (list carVal))
(display currVal)

Answer 5

您确实需要考虑您正在寻找的确切功能。

如果您想就地改变引用列表，那么您必须执行相当于追加的操作！ （如其他答案中所述）。但这是危险的，因为您可能有其他代码依赖于列表是不可变的，如果您打算这样做，您的过程需要有一个！最终标记出这种危险。

以更实用的方式，对您想要做的事情的一个简单的近似是：

(define (populateValues carVal currVal)
 (let ((ll (append currVal (list carVal))))
   (display ll)
   ll))

请注意，它会创建一个新列表，进行追加，显示结果，然后将新列表作为值返回。如果您无权访问中间值，这是一种有用的调试技术：绑定到变量，显示或记录它，然后返回它。