如何删除 AdvancedDataGrid 上的突出显示/选择

Question

这page 描述了如何重写 DataGrid 标头的 drawHighlightIndicator/drawSelectionIndicators 方法，但 AdvancedDataGrid 在 mx_internal 中没有“headerClass”。相反，它有一个 headerRenderer。

如何在 Flex 3 中的 AdvancedDataGrid 上删除那些被破坏的突出显示？

Answer 1

很抱歉发布不同的答案，但我没有足够的“点”对此做出直接评论。今天我遇到了完全相同的问题，发现这篇文章非常有帮助。

如果我错了，请纠正我，但我认为 mouseDownHandler 中缺少一行，这会阻止 AdvancedDataGrid 正确对数据进行排序（如果启用了数据排序）：

override protected function mouseDownHandler(event:MouseEvent):void
{
    super.mouseDownHandler(event);

    var s:Sprite = Sprite(
        selectionLayer.getChildByName("headerSelection"));

    if(s) s.graphics.clear();
}

尽管它可能很有用。

Answer 2

AdvancedDataGridBaseEx.as 中第 5468-5471 行中绘制的图形调用：

var g:Graphics = s.graphics;
g.clear();
g.beginFill(getStyle("rollOverColor")); //all I really wanted was to decrease the alpha here :(
g.drawRect(0, 0, w, h - 0.5);
g.endFill();

要摆脱此问题，您可以在扩展 AdvancedDataGrid 的类中执行此操作：

package
{
    import flash.display.Sprite;
    import flash.events.MouseEvent;

    import mx.controls.AdvancedDataGrid;

    public class AdvancedDataGridMinusHighlights extends AdvancedDataGrid
    {
        public function AdvancedDataGridMinusHighlights()
        {
            super();
        }

        override protected function mouseOverHandler(event:MouseEvent):void
        {
            super.mouseOverHandler(event);

            var s:Sprite = Sprite(
                selectionLayer.getChildByName("headerSelection"));

            if(s) s.graphics.clear();

        }

        override protected function mouseDownHandler(event:MouseEvent):void
        {
            super.mouseDownHandler(event);

            var s:Sprite = Sprite(
                selectionLayer.getChildByName("headerSelection"));

            if(s) s.graphics.clear();
        }

    }
}

尽管这是一个极其不优雅的解决方案，因为它所做的一切都清楚已经是什么绘制的。因为 AdvancedDataGridBaseEx 中的鼠标处理程序中有很多其他废话，所以您将无法轻松自定义标头的外观。

一个稍微优雅的（黑客）解决方案是将 AdvancedDataGridBaseEx 的完整源代码复制到 mx.controls 包中（我相信你们中的许多人都知道这种黑客，并且同样意识到其后果）。