XSLT 2.0 正则表达式问题（不同匹配的开始和结束元素）

Question

我已经稍微简化了问题，但我希望我仍然抓住了问题的本质。

假设我有以下简单的 XML 文件：

<main>
  outside1
  ===BEGIN===
    inside1
  ====END====
  outside2
  =BEGIN=
    inside2
  ==END==
  outside3
</main>

然后我可以使用以下 XSLT 2.0：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

<xsl:template match="text()">

  <xsl:analyze-string select="." regex="=+BEGIN=+">
     <xsl:matching-substring>
        <section/>
     </xsl:matching-substring>
     <xsl:non-matching-substring>
          <xsl:analyze-string select="." regex="=+END=+">  
             <xsl:matching-substring>
                <_section/>
             </xsl:matching-substring>
             <xsl:non-matching-substring>
                <xsl:value-of select="."/>
             </xsl:non-matching-substring>
          </xsl:analyze-string>
     </xsl:non-matching-substring>
  </xsl:analyze-string>

</xsl:template>

</xsl:stylesheet>

将其转换为以下内容：

<?xml version="1.0" encoding="UTF-8"?>
  outside1
  <section/>
    inside1
  <_section/>
  outside2
  <section/>
    inside2
  <_section/>
  outside3

以下是问题：

多个正则表达式

是否有更好的方法来匹配两个不同的正则表达式，而不是将它们嵌套在另一个正则表达式中就像上面所做的那样？

• 如果它们不容易像这样嵌套怎么办？
• 我可以使用 XSL 模板来匹配和转换 text() 中的正则表达式匹配项吗？
  • 在本例中，我有两个模板，每个模板对应一个正则表达式
  • 如果可能的话，这将是理想的解决方案

在正则表达式匹配上打开和关闭元素

显然，而不是：

<section/>
   inside
<_section/>

我最终真正想要的是：

<section>
   inside
</section>

那么如何你做这个吗？我不确定是否可以在一个正则表达式匹配中打开一个元素并在另一个正则表达式匹配中关闭它（即如果没有更接近的匹配怎么办？结果将不是格式良好的 XML！），但看起来像这项任务非常典型，必须有一个惯用的解决方案。

注意：我们可以假设部分不会重叠，因此也不会嵌套。我们还可以假设它们总是成对出现。

---

附加信息

所以本质上我试图完成 Perl 中简单的事情：

s/=+BEGIN=+/<section>/
s/=+END=+/<\/section>/

我正在寻找一种在 XSLT 中执行此操作的方法，因为：

• 对于正则表达式匹配的上下文，它会更加强大
  • （即它应该只转换 text() 节点）
• 在匹配各种 XML 实体方面它也会更加健壮

Answer 1

此转换：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 exclude-result-prefixes="xs"
>
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
    <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()">
   <xsl:analyze-string select="." flags="mx"
    regex="=+BEGIN=+((.|\n)*?)=+END=+">

   <xsl:matching-substring>
    <section><xsl:value-of select="regex-group(1)"/></section>
   </xsl:matching-substring>

   <xsl:non-matching-substring>
    <xsl:value-of select="."/>
   </xsl:non-matching-substring>
 </xsl:analyze-string>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<main>
  outside1
  ===BEGIN===
    inside1
  ====END====
  outside2
  =BEGIN=
    inside2
  ==END==
  outside3
</main>

产生所需的结果：

<main>
  outside1
  <section>
    inside1
  </section>
  outside2
  <section>
    inside2
  </section>
  outside3
</main>