使用accumulate 计算总和

Question

程序accumulate的定义如下：

(define (accumulate combiner null-value term a next b)
  (if (> a b) null-value
      (combiner (term a)
                (accumulate combiner null-value term (next a) next b))))

问题1：x^n ;解决方案：递归无累加

(define (expon x n)
  (if (> n 0) (* x
                 (expon x (- n 1))
              )
              1))

问题2：x + x^2 + x^4 + x^6 + ...+ ，计算给定的n 序列的前n 个元素。

问题3：1+x/1！ + x^2/2！ + ... + x^n/n!;计算给定 x,n 的总和 可能不正确的解决方案：

(define (exp1 x n)
 (define (term i)
   (define (term1 k) (/ x k))
   (accumulate * 1 term1 1 1+ i))
  (accumulate + 0 term 1 1+ n))

为什么前面的代码不正确：

(exp1 0 3) ->; 0 ;应该是1 （exp1 1 1）-> 1 ;应该是2

Answer 1

首先，我想说你的 EXP1 过程在根据累加定义时的运行水平太低，并且为了洞察力，用总和和阶乘重写它：

(define (sum term a b)
  (accumulate + 0 term a 1+ b))

(define (product term a b)
  (accumulate * 1 term a 1+ b))

(define (identity x) x)

(define (fact n)
  (if (= n 0)
      1
      (product identity 1 n)))

(define (exp1 x n)
  (define (term i)
    (/ (expon x i) (fact i)))
  (sum term 1 n))

现在回答你的问题：你的原因是得到 (EXP1 0 3) → 0 只不过是您忘记在系列开头添加 1，而只是计算 x/1！ + x^2/2！ + ... + x^n/n！

更改 EXP1 以包含缺失的术语可以按预期工作：

(define (exp1 x n)
    (define (term i)
          (/ (expon x i) (fact i)))
    (+ 1 (sum term 1 n)))

=> (exp1 0 3)
1
=> (exp1 1 1)
2