为什么我不能使用“CompactDatabase”在 DAO.DBEngine.36 中使用 VBscript？

Question

我正在尝试制作一个小型 VBScript 来压缩 MS Access 2007 数据库文件。

我的代码是：

Set acc2007 = CreateObject("DAO.DBEngine.36")
acc2007.CompactDatabase "C:\test.accdb", "C:\test2.accdb", Nothing, Nothing, ";pwd=test"
Set acc2007 = Nothing

当我从 32 位 cmd.exe 运行带有“cscript test.vbs”的三行时，出现此错误：

C:\test.vbs(10, 1) DAO。 DbEngine: 无法识别的数据库格式“C:\test.accdb”。

该数据库是使用 MS Access 2007 创建的，当我通过双击图标打开它时，我输入密码“test”，然后正常打开。顶部显示“Access 2007”，因此它具有正确的格式。

以下是我尝试使用的函数的文档： http://msdn.microsoft .com/en-us/library/bb220986.aspx

对象 DAO.DBEngine.36 已成功创建，因为我在该行上没有收到任何错误。有什么问题吗？

Answer 1

DAO 3.6 不支持新的 ACCDB 数据库格式。请尝试使用DAO.DBEngine.120。

这是一个适用于我的系统的示例。

Dim objFSO
Dim objEngine
Dim strLckFile
Dim strSrcName
Dim strDstName
Dim strPassword

strLckFile =  "C:\Access\webforums\foo.laccdb"
strSrcName =  "C:\Access\webforums\foo.accdb"
strDstName =  "C:\Access\webforums\compacted.accdb"
strBackup = "C:\Access\webforums\foobackup.accdb"
strPassword = "foo"

Set objEngine = CreateObject("DAO.DBEngine.120")

Set objFSO = CreateObject("Scripting.FileSystemObject")
If Not (objFSO.FileExists(strLckFile)) Then
    If (objFSO.FileExists(strBackup)) Then
        objFSO.DeleteFile strBackup
    End If
    If (objFSO.FileExists(strDstName)) Then
        objFSO.DeleteFile strDstName
    End If
    objFSO.CopyFile strSrcName, strBackup

    ''dbVersion120 = 128 
    objEngine.CompactDatabase strSrcName, strDstName, , 128, ";pwd=" & strPassword

    objFSO.DeleteFile strSrcName
    objFSO.MoveFile strDstName, strSrcName
End If 'LckFile

注意：我决定在压缩之前对数据库进行备份。最后，我删除原始（未压缩）数据库并将压缩后的数据库重命名为原始名称。如果您对此不感兴趣，您可以通过删除 objFSO 内容来简化此操作。

编辑：修改为检查锁定文件；如果发现什么也不做。

Answer 2

上述命令不适用于 Access 2007 和 2010。

虽然所有版本的 Windows 都可以追溯到 2000 年，甚至可能是 Windows 98，但对于 Access 2007 及更高版本，如果您使用的是新版本，则附带 Jet 引擎的副本格式（accdb），那么你需要使用新版本的Jet引擎，称为ACE。请注意，默认情况下，Windows 上并未安装此数据引擎，因此您必须从 微软。

当然，假设您已经安装了 Access 2007，那么您确实拥有了新的 Jet 引擎 (ACE)，并且不需要下载并安装上述软件。

您需要的新对象名称是 DAO.DBEngine.120，因此将代码更改为：

Set acc2007 = CreateObject("DAO.DBEngine.120") 

请注意，64 位版本也可用。